mirror of
https://github.com/edk2-porting/linux-next.git
synced 2024-12-27 06:34:11 +08:00
0b0bf7a3cc
The latest toolchains can produce a new ELF section in DSOs and
dynamically-linked executables. The new section ".gnu.hash" replaces
".hash", and allows for more efficient runtime symbol lookups by the
dynamic linker. The new ld option --hash-style={sysv|gnu|both} controls
whether to produce the old ".hash", the new ".gnu.hash", or both. In some
new systems such as Fedora Core 6, gcc by default passes --hash-style=gnu
to the linker, so that a standard invocation of "gcc -shared" results in
producing a DSO with only ".gnu.hash". The new ".gnu.hash" sections need
to be dealt with the same way as ".hash" sections in all respects; only the
dynamic linker cares about their contents. To work with older dynamic
linkers (i.e. preexisting releases of glibc), a binary must have the old
".hash" section. The --hash-style=both option produces binaries that a new
dynamic linker can use more efficiently, but an old dynamic linker can
still handle.
The new section runs afoul of the custom linker scripts used to build vDSO
images for the kernel. On ia64, the failure mode for this is a boot-time
panic because the vDSO's PT_IA_64_UNWIND segment winds up ill-formed.
This patch addresses the problem in two ways.
First, it mentions ".gnu.hash" in all the linker scripts alongside ".hash".
This produces correct vDSO images with --hash-style=sysv (or old tools),
with --hash-style=gnu, or with --hash-style=both.
Second, it passes the --hash-style=sysv option when building the vDSO
images, so that ".gnu.hash" is not actually produced. This is the most
conservative choice for compatibility with any old userland. There is some
concern that some ancient glibc builds (though not any known old production
system) might choke on --hash-style=both binaries. The optimizations
provided by the new style of hash section do not really matter for a DSO
with a tiny number of symbols, as the vDSO has. If someone wants to use
=gnu or =both for their vDSO builds and worry less about that
compatibility, just change the option and the linker script changes will
make any choice work fine.
Signed-off-by: Roland McGrath <roland@redhat.com>
Cc: "Luck, Tony" <tony.luck@intel.com>
Cc: Kyle McMartin <kyle@mcmartin.ca>
Cc: Paul Mackerras <paulus@samba.org>
Cc: Benjamin Herrenschmidt <benh@kernel.crashing.org>
Cc: Jeff Dike <jdike@addtoit.com>
Cc: Andi Kleen <ak@muc.de>
Cc: Sam Ravnborg <sam@ravnborg.org>
Signed-off-by: Andrew Morton <akpm@osdl.org>
Signed-off-by: Linus Torvalds <torvalds@osdl.org>
97 lines
2.6 KiB
ArmAsm
97 lines
2.6 KiB
ArmAsm
/*
|
|
* Linker script for gate DSO. The gate pages are an ELF shared object prelinked to its
|
|
* virtual address, with only one read-only segment and one execute-only segment (both fit
|
|
* in one page). This script controls its layout.
|
|
*/
|
|
|
|
|
|
#include <asm/system.h>
|
|
|
|
SECTIONS
|
|
{
|
|
. = GATE_ADDR + SIZEOF_HEADERS;
|
|
|
|
.hash : { *(.hash) } :readable
|
|
.gnu.hash : { *(.gnu.hash) }
|
|
.dynsym : { *(.dynsym) }
|
|
.dynstr : { *(.dynstr) }
|
|
.gnu.version : { *(.gnu.version) }
|
|
.gnu.version_d : { *(.gnu.version_d) }
|
|
.gnu.version_r : { *(.gnu.version_r) }
|
|
.dynamic : { *(.dynamic) } :readable :dynamic
|
|
|
|
/*
|
|
* This linker script is used both with -r and with -shared. For the layouts to match,
|
|
* we need to skip more than enough space for the dynamic symbol table et al. If this
|
|
* amount is insufficient, ld -shared will barf. Just increase it here.
|
|
*/
|
|
. = GATE_ADDR + 0x500;
|
|
|
|
.data.patch : {
|
|
__start_gate_mckinley_e9_patchlist = .;
|
|
*(.data.patch.mckinley_e9)
|
|
__end_gate_mckinley_e9_patchlist = .;
|
|
|
|
__start_gate_vtop_patchlist = .;
|
|
*(.data.patch.vtop)
|
|
__end_gate_vtop_patchlist = .;
|
|
|
|
__start_gate_fsyscall_patchlist = .;
|
|
*(.data.patch.fsyscall_table)
|
|
__end_gate_fsyscall_patchlist = .;
|
|
|
|
__start_gate_brl_fsys_bubble_down_patchlist = .;
|
|
*(.data.patch.brl_fsys_bubble_down)
|
|
__end_gate_brl_fsys_bubble_down_patchlist = .;
|
|
} :readable
|
|
.IA_64.unwind_info : { *(.IA_64.unwind_info*) }
|
|
.IA_64.unwind : { *(.IA_64.unwind*) } :readable :unwind
|
|
#ifdef HAVE_BUGGY_SEGREL
|
|
.text (GATE_ADDR + PAGE_SIZE) : { *(.text) *(.text.*) } :readable
|
|
#else
|
|
. = ALIGN (PERCPU_PAGE_SIZE) + (. & (PERCPU_PAGE_SIZE - 1));
|
|
.text : { *(.text) *(.text.*) } :epc
|
|
#endif
|
|
|
|
/DISCARD/ : {
|
|
*(.got.plt) *(.got)
|
|
*(.data .data.* .gnu.linkonce.d.*)
|
|
*(.dynbss)
|
|
*(.bss .bss.* .gnu.linkonce.b.*)
|
|
*(__ex_table)
|
|
*(__mca_table)
|
|
}
|
|
}
|
|
|
|
/*
|
|
* We must supply the ELF program headers explicitly to get just one
|
|
* PT_LOAD segment, and set the flags explicitly to make segments read-only.
|
|
*/
|
|
PHDRS
|
|
{
|
|
readable PT_LOAD FILEHDR PHDRS FLAGS(4); /* PF_R */
|
|
#ifndef HAVE_BUGGY_SEGREL
|
|
epc PT_LOAD FILEHDR PHDRS FLAGS(1); /* PF_X */
|
|
#endif
|
|
dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
|
|
unwind 0x70000001; /* PT_IA_64_UNWIND, but ld doesn't match the name */
|
|
}
|
|
|
|
/*
|
|
* This controls what symbols we export from the DSO.
|
|
*/
|
|
VERSION
|
|
{
|
|
LINUX_2.5 {
|
|
global:
|
|
__kernel_syscall_via_break;
|
|
__kernel_syscall_via_epc;
|
|
__kernel_sigtramp;
|
|
|
|
local: *;
|
|
};
|
|
}
|
|
|
|
/* The ELF entry point can be used to set the AT_SYSINFO value. */
|
|
ENTRY(__kernel_syscall_via_epc)
|