mirror of
https://github.com/edk2-porting/linux-next.git
synced 2024-12-25 13:43:55 +08:00
13c06be399
This patch adds an implementation of setjmp and longjmp to UML, allowing access to the inside of a jmpbuf without needing the access macros formerly provided by libc. The implementation is stolen from klibc. I copy the relevant files into arch/um. I have another patch which avoids the copying, but requires klibc be in the tree. setjmp and longjmp users required some tweaking. Includes of <setjmp.h> were removed and includes of the UML longjmp.h were added where necessary. There are also replacements of siglongjmp with UML_LONGJMP which I somehow missed earlier. Signed-off-by: Jeff Dike <jdike@addtoit.com> Signed-off-by: Andrew Morton <akpm@osdl.org> Signed-off-by: Linus Torvalds <torvalds@osdl.org>
55 lines
932 B
ArmAsm
55 lines
932 B
ArmAsm
#
|
|
# arch/x86_64/setjmp.S
|
|
#
|
|
# setjmp/longjmp for the x86-64 architecture
|
|
#
|
|
|
|
#
|
|
# The jmp_buf is assumed to contain the following, in order:
|
|
# %rbx
|
|
# %rsp (post-return)
|
|
# %rbp
|
|
# %r12
|
|
# %r13
|
|
# %r14
|
|
# %r15
|
|
# <return address>
|
|
#
|
|
|
|
.text
|
|
.align 4
|
|
.globl setjmp
|
|
.type setjmp, @function
|
|
setjmp:
|
|
pop %rsi # Return address, and adjust the stack
|
|
xorl %eax,%eax # Return value
|
|
movq %rbx,(%rdi)
|
|
movq %rsp,8(%rdi) # Post-return %rsp!
|
|
push %rsi # Make the call/return stack happy
|
|
movq %rbp,16(%rdi)
|
|
movq %r12,24(%rdi)
|
|
movq %r13,32(%rdi)
|
|
movq %r14,40(%rdi)
|
|
movq %r15,48(%rdi)
|
|
movq %rsi,56(%rdi) # Return address
|
|
ret
|
|
|
|
.size setjmp,.-setjmp
|
|
|
|
.text
|
|
.align 4
|
|
.globl longjmp
|
|
.type longjmp, @function
|
|
longjmp:
|
|
movl %esi,%eax # Return value (int)
|
|
movq (%rdi),%rbx
|
|
movq 8(%rdi),%rsp
|
|
movq 16(%rdi),%rbp
|
|
movq 24(%rdi),%r12
|
|
movq 32(%rdi),%r13
|
|
movq 40(%rdi),%r14
|
|
movq 48(%rdi),%r15
|
|
jmp *56(%rdi)
|
|
|
|
.size longjmp,.-longjmp
|