mirror of
https://github.com/edk2-porting/linux-next.git
synced 2024-12-26 06:04:14 +08:00
276c974ac7
When compiling uml on x86_64: MODPOST vmlinux.o WARNING: vmlinux.o (.__syscall_stub.2): unexpected non-allocatable section. Did you forget to use "ax"/"aw" in a .S file? Note that for example <linux/init.h> contains section definitions for use in .S files. Because modpost checks for missing SHF_ALLOC section flag. So just add it. Signed-off-by: WANG Cong <amwang@redhat.com> Cc: Jeff Dike <jdike@addtoit.com> Cc: Sam Ravnborg <sam@ravnborg.org> Signed-off-by: Andrew Morton <akpm@linux-foundation.org> Signed-off-by: Linus Torvalds <torvalds@linux-foundation.org>
67 lines
1.1 KiB
ArmAsm
67 lines
1.1 KiB
ArmAsm
#include "as-layout.h"
|
|
|
|
.globl syscall_stub
|
|
.section .__syscall_stub, "ax"
|
|
syscall_stub:
|
|
syscall
|
|
/* We don't have 64-bit constants, so this constructs the address
|
|
* we need.
|
|
*/
|
|
movq $(STUB_DATA >> 32), %rbx
|
|
salq $32, %rbx
|
|
movq $(STUB_DATA & 0xffffffff), %rcx
|
|
or %rcx, %rbx
|
|
movq %rax, (%rbx)
|
|
int3
|
|
|
|
.globl batch_syscall_stub
|
|
batch_syscall_stub:
|
|
mov $(STUB_DATA >> 32), %rbx
|
|
sal $32, %rbx
|
|
mov $(STUB_DATA & 0xffffffff), %rax
|
|
or %rax, %rbx
|
|
/* load pointer to first operation */
|
|
mov %rbx, %rsp
|
|
add $0x10, %rsp
|
|
again:
|
|
/* load length of additional data */
|
|
mov 0x0(%rsp), %rax
|
|
|
|
/* if(length == 0) : end of list */
|
|
/* write possible 0 to header */
|
|
mov %rax, 8(%rbx)
|
|
cmp $0, %rax
|
|
jz done
|
|
|
|
/* save current pointer */
|
|
mov %rsp, 8(%rbx)
|
|
|
|
/* skip additional data */
|
|
add %rax, %rsp
|
|
|
|
/* load syscall-# */
|
|
pop %rax
|
|
|
|
/* load syscall params */
|
|
pop %rdi
|
|
pop %rsi
|
|
pop %rdx
|
|
pop %r10
|
|
pop %r8
|
|
pop %r9
|
|
|
|
/* execute syscall */
|
|
syscall
|
|
|
|
/* check return value */
|
|
pop %rcx
|
|
cmp %rcx, %rax
|
|
je again
|
|
|
|
done:
|
|
/* save return value */
|
|
mov %rax, (%rbx)
|
|
|
|
/* stop */
|
|
int3
|