mirror of
https://github.com/edk2-porting/linux-next.git
synced 2024-12-23 04:34:11 +08:00
f56e65dff6
Pull initial set_fs() removal from Al Viro:
"Christoph's set_fs base series + fixups"
* 'work.set_fs' of git://git.kernel.org/pub/scm/linux/kernel/git/viro/vfs:
fs: Allow a NULL pos pointer to __kernel_read
fs: Allow a NULL pos pointer to __kernel_write
powerpc: remove address space overrides using set_fs()
powerpc: use non-set_fs based maccess routines
x86: remove address space overrides using set_fs()
x86: make TASK_SIZE_MAX usable from assembly code
x86: move PAGE_OFFSET, TASK_SIZE & friends to page_{32,64}_types.h
lkdtm: remove set_fs-based tests
test_bitmap: remove user bitmap tests
uaccess: add infrastructure for kernel builds with set_fs()
fs: don't allow splice read/write without explicit ops
fs: don't allow kernel reads and writes without iter ops
sysctl: Convert to iter interfaces
proc: add a read_iter method to proc proc_ops
proc: cleanup the compat vs no compat file ops
proc: remove a level of indentation in proc_get_inode
119 lines
2.7 KiB
ArmAsm
119 lines
2.7 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
* __put_user functions.
|
|
*
|
|
* (C) Copyright 2005 Linus Torvalds
|
|
* (C) Copyright 2005 Andi Kleen
|
|
* (C) Copyright 2008 Glauber Costa
|
|
*
|
|
* These functions have a non-standard call interface
|
|
* to make them more efficient, especially as they
|
|
* return an error value in addition to the "real"
|
|
* return value.
|
|
*/
|
|
#include <linux/linkage.h>
|
|
#include <asm/thread_info.h>
|
|
#include <asm/errno.h>
|
|
#include <asm/asm.h>
|
|
#include <asm/smap.h>
|
|
#include <asm/export.h>
|
|
|
|
|
|
/*
|
|
* __put_user_X
|
|
*
|
|
* Inputs: %eax[:%edx] contains the data
|
|
* %ecx contains the address
|
|
*
|
|
* Outputs: %ecx is error code (0 or -EFAULT)
|
|
*
|
|
* Clobbers: %ebx needed for task pointer
|
|
*
|
|
* These functions should not modify any other registers,
|
|
* as they get called from within inline assembly.
|
|
*/
|
|
|
|
#ifdef CONFIG_X86_5LEVEL
|
|
#define LOAD_TASK_SIZE_MINUS_N(n) \
|
|
ALTERNATIVE __stringify(mov $((1 << 47) - 4096 - (n)),%rbx), \
|
|
__stringify(mov $((1 << 56) - 4096 - (n)),%rbx), X86_FEATURE_LA57
|
|
#else
|
|
#define LOAD_TASK_SIZE_MINUS_N(n) \
|
|
mov $(TASK_SIZE_MAX - (n)),%_ASM_BX
|
|
#endif
|
|
|
|
.text
|
|
SYM_FUNC_START(__put_user_1)
|
|
LOAD_TASK_SIZE_MINUS_N(0)
|
|
cmp %_ASM_BX,%_ASM_CX
|
|
jae .Lbad_put_user
|
|
SYM_INNER_LABEL(__put_user_nocheck_1, SYM_L_GLOBAL)
|
|
ASM_STAC
|
|
1: movb %al,(%_ASM_CX)
|
|
xor %ecx,%ecx
|
|
ASM_CLAC
|
|
ret
|
|
SYM_FUNC_END(__put_user_1)
|
|
EXPORT_SYMBOL(__put_user_1)
|
|
EXPORT_SYMBOL(__put_user_nocheck_1)
|
|
|
|
SYM_FUNC_START(__put_user_2)
|
|
LOAD_TASK_SIZE_MINUS_N(1)
|
|
cmp %_ASM_BX,%_ASM_CX
|
|
jae .Lbad_put_user
|
|
SYM_INNER_LABEL(__put_user_nocheck_2, SYM_L_GLOBAL)
|
|
ASM_STAC
|
|
2: movw %ax,(%_ASM_CX)
|
|
xor %ecx,%ecx
|
|
ASM_CLAC
|
|
ret
|
|
SYM_FUNC_END(__put_user_2)
|
|
EXPORT_SYMBOL(__put_user_2)
|
|
EXPORT_SYMBOL(__put_user_nocheck_2)
|
|
|
|
SYM_FUNC_START(__put_user_4)
|
|
LOAD_TASK_SIZE_MINUS_N(3)
|
|
cmp %_ASM_BX,%_ASM_CX
|
|
jae .Lbad_put_user
|
|
SYM_INNER_LABEL(__put_user_nocheck_4, SYM_L_GLOBAL)
|
|
ASM_STAC
|
|
3: movl %eax,(%_ASM_CX)
|
|
xor %ecx,%ecx
|
|
ASM_CLAC
|
|
ret
|
|
SYM_FUNC_END(__put_user_4)
|
|
EXPORT_SYMBOL(__put_user_4)
|
|
EXPORT_SYMBOL(__put_user_nocheck_4)
|
|
|
|
SYM_FUNC_START(__put_user_8)
|
|
LOAD_TASK_SIZE_MINUS_N(7)
|
|
cmp %_ASM_BX,%_ASM_CX
|
|
jae .Lbad_put_user
|
|
SYM_INNER_LABEL(__put_user_nocheck_8, SYM_L_GLOBAL)
|
|
ASM_STAC
|
|
4: mov %_ASM_AX,(%_ASM_CX)
|
|
#ifdef CONFIG_X86_32
|
|
5: movl %edx,4(%_ASM_CX)
|
|
#endif
|
|
xor %ecx,%ecx
|
|
ASM_CLAC
|
|
RET
|
|
SYM_FUNC_END(__put_user_8)
|
|
EXPORT_SYMBOL(__put_user_8)
|
|
EXPORT_SYMBOL(__put_user_nocheck_8)
|
|
|
|
SYM_CODE_START_LOCAL(.Lbad_put_user_clac)
|
|
ASM_CLAC
|
|
.Lbad_put_user:
|
|
movl $-EFAULT,%ecx
|
|
RET
|
|
SYM_CODE_END(.Lbad_put_user_clac)
|
|
|
|
_ASM_EXTABLE_UA(1b, .Lbad_put_user_clac)
|
|
_ASM_EXTABLE_UA(2b, .Lbad_put_user_clac)
|
|
_ASM_EXTABLE_UA(3b, .Lbad_put_user_clac)
|
|
_ASM_EXTABLE_UA(4b, .Lbad_put_user_clac)
|
|
#ifdef CONFIG_X86_32
|
|
_ASM_EXTABLE_UA(5b, .Lbad_put_user_clac)
|
|
#endif
|