mirror of
https://github.com/edk2-porting/linux-next.git
synced 2024-12-25 21:54:06 +08:00
163159aad7
When using GCC as compiler and LLVM's lld as linker, linking setup.elf
fails:
LD arch/x86/boot/setup.elf
ld.lld: error: init sections too big!
This happens because GCC generates .eh_frame sections for most of the
files in that directory, then ld.lld places the merged section before
__end_init, triggering an assert in the linker script.
Fix this by discarding the .eh_frame sections, as suggested by Boris.
The kernel proper linker script discards them too.
[ bp: Going back in history, 64-bit kernel proper has been discarding
.eh_frame since 2002:
commit acca80acefe20420e69561cf55be64f16c34ea97
Author: Andi Kleen <ak@muc.de>
Date: Tue Oct 29 23:54:35 2002 -0800
[PATCH] x86-64 updates for 2.5.44
...
- Remove the .eh_frame on linking. This saves several hundred KB in the
bzImage
]
Suggested-by: Borislav Petkov <bp@alien8.de>
Signed-off-by: Ilie Halip <ilie.halip@gmail.com>
Signed-off-by: Borislav Petkov <bp@suse.de>
Reviewed-by: Nick Desaulniers <ndesaulniers@google.com
Cc: Andy Lutomirski <luto@kernel.org>
Cc: clang-built-linux@googlegroups.com
Cc: "H. Peter Anvin" <hpa@zytor.com>
Cc: Ingo Molnar <mingo@redhat.com>
Cc: Thomas Gleixner <tglx@linutronix.de>
Cc: x86-ml <x86@kernel.org>
Link: https://lore.kernel.org/lkml/20191118175223.GM6363@zn.tnic/
Link: https://github.com/ClangBuiltLinux/linux/issues/760
Link: https://lkml.kernel.org/r/20191126144545.19354-1-ilie.halip@gmail.com
68 lines
1.1 KiB
Plaintext
68 lines
1.1 KiB
Plaintext
/*
|
|
* setup.ld
|
|
*
|
|
* Linker script for the i386 setup code
|
|
*/
|
|
OUTPUT_FORMAT("elf32-i386")
|
|
OUTPUT_ARCH(i386)
|
|
ENTRY(_start)
|
|
|
|
SECTIONS
|
|
{
|
|
. = 0;
|
|
.bstext : { *(.bstext) }
|
|
.bsdata : { *(.bsdata) }
|
|
|
|
. = 495;
|
|
.header : { *(.header) }
|
|
.entrytext : { *(.entrytext) }
|
|
.inittext : { *(.inittext) }
|
|
.initdata : { *(.initdata) }
|
|
__end_init = .;
|
|
|
|
.text : { *(.text) }
|
|
.text32 : { *(.text32) }
|
|
|
|
. = ALIGN(16);
|
|
.rodata : { *(.rodata*) }
|
|
|
|
.videocards : {
|
|
video_cards = .;
|
|
*(.videocards)
|
|
video_cards_end = .;
|
|
}
|
|
|
|
. = ALIGN(16);
|
|
.data : { *(.data*) }
|
|
|
|
.signature : {
|
|
setup_sig = .;
|
|
LONG(0x5a5aaa55)
|
|
}
|
|
|
|
|
|
. = ALIGN(16);
|
|
.bss :
|
|
{
|
|
__bss_start = .;
|
|
*(.bss)
|
|
__bss_end = .;
|
|
}
|
|
. = ALIGN(16);
|
|
_end = .;
|
|
|
|
/DISCARD/ : {
|
|
*(.eh_frame)
|
|
*(.note*)
|
|
}
|
|
|
|
/*
|
|
* The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
|
|
*/
|
|
. = ASSERT(_end <= 0x8000, "Setup too big!");
|
|
. = ASSERT(hdr == 0x1f1, "The setup header has the wrong offset!");
|
|
/* Necessary for the very-old-loader check to work... */
|
|
. = ASSERT(__end_init <= 5*512, "init sections too big!");
|
|
|
|
}
|