mirror of
https://github.com/edk2-porting/linux-next.git
synced 2024-12-27 06:34:11 +08:00
b24413180f
Many source files in the tree are missing licensing information, which makes it harder for compliance tools to determine the correct license. By default all files without license information are under the default license of the kernel, which is GPL version 2. Update the files which contain no license information with the 'GPL-2.0' SPDX license identifier. The SPDX identifier is a legally binding shorthand, which can be used instead of the full boiler plate text. This patch is based on work done by Thomas Gleixner and Kate Stewart and Philippe Ombredanne. How this work was done: Patches were generated and checked against linux-4.14-rc6 for a subset of the use cases: - file had no licensing information it it. - file was a */uapi/* one with no licensing information in it, - file was a */uapi/* one with existing licensing information, Further patches will be generated in subsequent months to fix up cases where non-standard license headers were used, and references to license had to be inferred by heuristics based on keywords. The analysis to determine which SPDX License Identifier to be applied to a file was done in a spreadsheet of side by side results from of the output of two independent scanners (ScanCode & Windriver) producing SPDX tag:value files created by Philippe Ombredanne. Philippe prepared the base worksheet, and did an initial spot review of a few 1000 files. The 4.13 kernel was the starting point of the analysis with 60,537 files assessed. Kate Stewart did a file by file comparison of the scanner results in the spreadsheet to determine which SPDX license identifier(s) to be applied to the file. She confirmed any determination that was not immediately clear with lawyers working with the Linux Foundation. Criteria used to select files for SPDX license identifier tagging was: - Files considered eligible had to be source code files. - Make and config files were included as candidates if they contained >5 lines of source - File already had some variant of a license header in it (even if <5 lines). All documentation files were explicitly excluded. The following heuristics were used to determine which SPDX license identifiers to apply. - when both scanners couldn't find any license traces, file was considered to have no license information in it, and the top level COPYING file license applied. For non */uapi/* files that summary was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 11139 and resulted in the first patch in this series. If that file was a */uapi/* path one, it was "GPL-2.0 WITH Linux-syscall-note" otherwise it was "GPL-2.0". Results of that was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 WITH Linux-syscall-note 930 and resulted in the second patch in this series. - if a file had some form of licensing information in it, and was one of the */uapi/* ones, it was denoted with the Linux-syscall-note if any GPL family license was found in the file or had no licensing in it (per prior point). Results summary: SPDX license identifier # files ---------------------------------------------------|------ GPL-2.0 WITH Linux-syscall-note 270 GPL-2.0+ WITH Linux-syscall-note 169 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-2-Clause) 21 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-3-Clause) 17 LGPL-2.1+ WITH Linux-syscall-note 15 GPL-1.0+ WITH Linux-syscall-note 14 ((GPL-2.0+ WITH Linux-syscall-note) OR BSD-3-Clause) 5 LGPL-2.0+ WITH Linux-syscall-note 4 LGPL-2.1 WITH Linux-syscall-note 3 ((GPL-2.0 WITH Linux-syscall-note) OR MIT) 3 ((GPL-2.0 WITH Linux-syscall-note) AND MIT) 1 and that resulted in the third patch in this series. - when the two scanners agreed on the detected license(s), that became the concluded license(s). - when there was disagreement between the two scanners (one detected a license but the other didn't, or they both detected different licenses) a manual inspection of the file occurred. - In most cases a manual inspection of the information in the file resulted in a clear resolution of the license that should apply (and which scanner probably needed to revisit its heuristics). - When it was not immediately clear, the license identifier was confirmed with lawyers working with the Linux Foundation. - If there was any question as to the appropriate license identifier, the file was flagged for further research and to be revisited later in time. In total, over 70 hours of logged manual review was done on the spreadsheet to determine the SPDX license identifiers to apply to the source files by Kate, Philippe, Thomas and, in some cases, confirmation by lawyers working with the Linux Foundation. Kate also obtained a third independent scan of the 4.13 code base from FOSSology, and compared selected files where the other two scanners disagreed against that SPDX file, to see if there was new insights. The Windriver scanner is based on an older version of FOSSology in part, so they are related. Thomas did random spot checks in about 500 files from the spreadsheets for the uapi headers and agreed with SPDX license identifier in the files he inspected. For the non-uapi files Thomas did random spot checks in about 15000 files. In initial set of patches against 4.14-rc6, 3 files were found to have copy/paste license identifier errors, and have been fixed to reflect the correct identifier. Additionally Philippe spent 10 hours this week doing a detailed manual inspection and review of the 12,461 patched files from the initial patch version early this week with: - a full scancode scan run, collecting the matched texts, detected license ids and scores - reviewing anything where there was a license detected (about 500+ files) to ensure that the applied SPDX license was correct - reviewing anything where there was no detection but the patch license was not GPL-2.0 WITH Linux-syscall-note to ensure that the applied SPDX license was correct This produced a worksheet with 20 files needing minor correction. This worksheet was then exported into 3 different .csv files for the different types of files to be modified. These .csv files were then reviewed by Greg. Thomas wrote a script to parse the csv files and add the proper SPDX tag to the file, in the format that the file expected. This script was further refined by Greg based on the output to detect more types of files automatically and to distinguish between header and source .c files (which need different comment types.) Finally Greg ran the script using the .csv files to generate the patches. Reviewed-by: Kate Stewart <kstewart@linuxfoundation.org> Reviewed-by: Philippe Ombredanne <pombredanne@nexb.com> Reviewed-by: Thomas Gleixner <tglx@linutronix.de> Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
219 lines
5.2 KiB
ArmAsm
219 lines
5.2 KiB
ArmAsm
! SPDX-License-Identifier: GPL-2.0
|
|
!
|
|
! Fast SH memcpy
|
|
!
|
|
! by Toshiyasu Morita (tm@netcom.com)
|
|
! hacked by J"orn Rernnecke (joern.rennecke@superh.com) ("o for o-umlaut)
|
|
! SH5 code Copyright 2002 SuperH Ltd.
|
|
!
|
|
! Entry: ARG0: destination pointer
|
|
! ARG1: source pointer
|
|
! ARG2: byte count
|
|
!
|
|
! Exit: RESULT: destination pointer
|
|
! any other registers in the range r0-r7: trashed
|
|
!
|
|
! Notes: Usually one wants to do small reads and write a longword, but
|
|
! unfortunately it is difficult in some cases to concatanate bytes
|
|
! into a longword on the SH, so this does a longword read and small
|
|
! writes.
|
|
!
|
|
! This implementation makes two assumptions about how it is called:
|
|
!
|
|
! 1.: If the byte count is nonzero, the address of the last byte to be
|
|
! copied is unsigned greater than the address of the first byte to
|
|
! be copied. This could be easily swapped for a signed comparison,
|
|
! but the algorithm used needs some comparison.
|
|
!
|
|
! 2.: When there are two or three bytes in the last word of an 11-or-more
|
|
! bytes memory chunk to b copied, the rest of the word can be read
|
|
! without side effects.
|
|
! This could be easily changed by increasing the minimum size of
|
|
! a fast memcpy and the amount subtracted from r7 before L_2l_loop be 2,
|
|
! however, this would cost a few extra cyles on average.
|
|
! For SHmedia, the assumption is that any quadword can be read in its
|
|
! enirety if at least one byte is included in the copy.
|
|
|
|
/* Imported into Linux kernel by Richard Curnow. This is used to implement the
|
|
__copy_user function in the general case, so it has to be a distinct
|
|
function from intra-kernel memcpy to allow for exception fix-ups in the
|
|
event that the user pointer is bad somewhere in the copy (e.g. due to
|
|
running off the end of the vma).
|
|
|
|
Note, this algorithm will be slightly wasteful in the case where the source
|
|
and destination pointers are equally aligned, because the stlo/sthi pairs
|
|
could then be merged back into single stores. If there are a lot of cache
|
|
misses, this is probably offset by the stall lengths on the preloads.
|
|
|
|
*/
|
|
|
|
/* NOTE : Prefetches removed and allocos guarded by synco to avoid TAKum03020
|
|
* erratum. The first two prefetches are nop-ed out to avoid upsetting the
|
|
* instruction counts used in the jump address calculation.
|
|
* */
|
|
|
|
.section .text..SHmedia32,"ax"
|
|
.little
|
|
.balign 32
|
|
.global copy_user_memcpy
|
|
.global copy_user_memcpy_end
|
|
copy_user_memcpy:
|
|
|
|
#define LDUAQ(P,O,D0,D1) ldlo.q P,O,D0; ldhi.q P,O+7,D1
|
|
#define STUAQ(P,O,D0,D1) stlo.q P,O,D0; sthi.q P,O+7,D1
|
|
#define LDUAL(P,O,D0,D1) ldlo.l P,O,D0; ldhi.l P,O+3,D1
|
|
#define STUAL(P,O,D0,D1) stlo.l P,O,D0; sthi.l P,O+3,D1
|
|
|
|
nop ! ld.b r3,0,r63 ! TAKum03020
|
|
pta/l Large,tr0
|
|
movi 25,r0
|
|
bgeu/u r4,r0,tr0
|
|
nsb r4,r0
|
|
shlli r0,5,r0
|
|
movi (L1-L0+63*32 + 1) & 0xffff,r1
|
|
sub r1, r0, r0
|
|
L0: ptrel r0,tr0
|
|
add r2,r4,r5
|
|
ptabs r18,tr1
|
|
add r3,r4,r6
|
|
blink tr0,r63
|
|
|
|
/* Rearranged to make cut2 safe */
|
|
.balign 8
|
|
L4_7: /* 4..7 byte memcpy cntd. */
|
|
stlo.l r2, 0, r0
|
|
or r6, r7, r6
|
|
sthi.l r5, -1, r6
|
|
stlo.l r5, -4, r6
|
|
blink tr1,r63
|
|
|
|
.balign 8
|
|
L1: /* 0 byte memcpy */
|
|
nop
|
|
blink tr1,r63
|
|
nop
|
|
nop
|
|
nop
|
|
nop
|
|
|
|
L2_3: /* 2 or 3 byte memcpy cntd. */
|
|
st.b r5,-1,r6
|
|
blink tr1,r63
|
|
|
|
/* 1 byte memcpy */
|
|
ld.b r3,0,r0
|
|
st.b r2,0,r0
|
|
blink tr1,r63
|
|
|
|
L8_15: /* 8..15 byte memcpy cntd. */
|
|
stlo.q r2, 0, r0
|
|
or r6, r7, r6
|
|
sthi.q r5, -1, r6
|
|
stlo.q r5, -8, r6
|
|
blink tr1,r63
|
|
|
|
/* 2 or 3 byte memcpy */
|
|
ld.b r3,0,r0
|
|
nop ! ld.b r2,0,r63 ! TAKum03020
|
|
ld.b r3,1,r1
|
|
st.b r2,0,r0
|
|
pta/l L2_3,tr0
|
|
ld.b r6,-1,r6
|
|
st.b r2,1,r1
|
|
blink tr0, r63
|
|
|
|
/* 4 .. 7 byte memcpy */
|
|
LDUAL (r3, 0, r0, r1)
|
|
pta L4_7, tr0
|
|
ldlo.l r6, -4, r7
|
|
or r0, r1, r0
|
|
sthi.l r2, 3, r0
|
|
ldhi.l r6, -1, r6
|
|
blink tr0, r63
|
|
|
|
/* 8 .. 15 byte memcpy */
|
|
LDUAQ (r3, 0, r0, r1)
|
|
pta L8_15, tr0
|
|
ldlo.q r6, -8, r7
|
|
or r0, r1, r0
|
|
sthi.q r2, 7, r0
|
|
ldhi.q r6, -1, r6
|
|
blink tr0, r63
|
|
|
|
/* 16 .. 24 byte memcpy */
|
|
LDUAQ (r3, 0, r0, r1)
|
|
LDUAQ (r3, 8, r8, r9)
|
|
or r0, r1, r0
|
|
sthi.q r2, 7, r0
|
|
or r8, r9, r8
|
|
sthi.q r2, 15, r8
|
|
ldlo.q r6, -8, r7
|
|
ldhi.q r6, -1, r6
|
|
stlo.q r2, 8, r8
|
|
stlo.q r2, 0, r0
|
|
or r6, r7, r6
|
|
sthi.q r5, -1, r6
|
|
stlo.q r5, -8, r6
|
|
blink tr1,r63
|
|
|
|
Large:
|
|
! ld.b r2, 0, r63 ! TAKum03020
|
|
pta/l Loop_ua, tr1
|
|
ori r3, -8, r7
|
|
sub r2, r7, r22
|
|
sub r3, r2, r6
|
|
add r2, r4, r5
|
|
ldlo.q r3, 0, r0
|
|
addi r5, -16, r5
|
|
movi 64+8, r27 ! could subtract r7 from that.
|
|
stlo.q r2, 0, r0
|
|
sthi.q r2, 7, r0
|
|
ldx.q r22, r6, r0
|
|
bgtu/l r27, r4, tr1
|
|
|
|
addi r5, -48, r27
|
|
pta/l Loop_line, tr0
|
|
addi r6, 64, r36
|
|
addi r6, -24, r19
|
|
addi r6, -16, r20
|
|
addi r6, -8, r21
|
|
|
|
Loop_line:
|
|
! ldx.q r22, r36, r63 ! TAKum03020
|
|
alloco r22, 32
|
|
synco
|
|
addi r22, 32, r22
|
|
ldx.q r22, r19, r23
|
|
sthi.q r22, -25, r0
|
|
ldx.q r22, r20, r24
|
|
ldx.q r22, r21, r25
|
|
stlo.q r22, -32, r0
|
|
ldx.q r22, r6, r0
|
|
sthi.q r22, -17, r23
|
|
sthi.q r22, -9, r24
|
|
sthi.q r22, -1, r25
|
|
stlo.q r22, -24, r23
|
|
stlo.q r22, -16, r24
|
|
stlo.q r22, -8, r25
|
|
bgeu r27, r22, tr0
|
|
|
|
Loop_ua:
|
|
addi r22, 8, r22
|
|
sthi.q r22, -1, r0
|
|
stlo.q r22, -8, r0
|
|
ldx.q r22, r6, r0
|
|
bgtu/l r5, r22, tr1
|
|
|
|
add r3, r4, r7
|
|
ldlo.q r7, -8, r1
|
|
sthi.q r22, 7, r0
|
|
ldhi.q r7, -1, r7
|
|
ptabs r18,tr1
|
|
stlo.q r22, 0, r0
|
|
or r1, r7, r1
|
|
sthi.q r5, 15, r1
|
|
stlo.q r5, 8, r1
|
|
blink tr1, r63
|
|
copy_user_memcpy_end:
|
|
nop
|