mirror of
https://github.com/edk2-porting/linux-next.git
synced 2024-12-18 10:13:57 +08:00
dca230f00d
Optimized version of copy_page() was written with assumption that cache
line size is 32 bytes. On Cortex-A8 cache line size is 64 bytes.
This patch tries to generalize copy_page() to work with any cache line
size if cache line size is multiple of 16 and page size is multiple of
two cache line size.
After this optimization we've got ~25% speedup on OMAP3(tested in
userspace).
There is test for kernelspace which trigger copy-on-write after fork():
#include <stdlib.h>
#include <string.h>
#include <unistd.h>
#define BUF_SIZE (10000*4096)
#define NFORK 200
int main(int argc, char **argv)
{
char *buf = malloc(BUF_SIZE);
int i;
memset(buf, 0, BUF_SIZE);
for(i = 0; i < NFORK; i++) {
if (fork()) {
wait(NULL);
} else {
int j;
for(j = 0; j < BUF_SIZE; j+= 4096)
buf[j] = (j & 0xFF) + 1;
break;
}
}
free(buf);
return 0;
}
Before optimization this test takes ~66 seconds, after optimization
takes ~56 seconds.
Signed-off-by: Siarhei Siamashka <siarhei.siamashka@nokia.com>
Signed-off-by: Kirill A. Shutemov <kirill@shutemov.name>
Signed-off-by: Russell King <rmk+kernel@arm.linux.org.uk>
48 lines
1.3 KiB
ArmAsm
48 lines
1.3 KiB
ArmAsm
/*
|
|
* linux/arch/arm/lib/copypage.S
|
|
*
|
|
* Copyright (C) 1995-1999 Russell King
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License version 2 as
|
|
* published by the Free Software Foundation.
|
|
*
|
|
* ASM optimised string functions
|
|
*/
|
|
#include <linux/linkage.h>
|
|
#include <asm/assembler.h>
|
|
#include <asm/asm-offsets.h>
|
|
#include <asm/cache.h>
|
|
|
|
#define COPY_COUNT (PAGE_SZ / (2 * L1_CACHE_BYTES) PLD( -1 ))
|
|
|
|
.text
|
|
.align 5
|
|
/*
|
|
* StrongARM optimised copy_page routine
|
|
* now 1.78bytes/cycle, was 1.60 bytes/cycle (50MHz bus -> 89MB/s)
|
|
* Note that we probably achieve closer to the 100MB/s target with
|
|
* the core clock switching.
|
|
*/
|
|
ENTRY(copy_page)
|
|
stmfd sp!, {r4, lr} @ 2
|
|
PLD( pld [r1, #0] )
|
|
PLD( pld [r1, #L1_CACHE_BYTES] )
|
|
mov r2, #COPY_COUNT @ 1
|
|
ldmia r1!, {r3, r4, ip, lr} @ 4+1
|
|
1: PLD( pld [r1, #2 * L1_CACHE_BYTES])
|
|
PLD( pld [r1, #3 * L1_CACHE_BYTES])
|
|
2:
|
|
.rept (2 * L1_CACHE_BYTES / 16 - 1)
|
|
stmia r0!, {r3, r4, ip, lr} @ 4
|
|
ldmia r1!, {r3, r4, ip, lr} @ 4
|
|
.endr
|
|
subs r2, r2, #1 @ 1
|
|
stmia r0!, {r3, r4, ip, lr} @ 4
|
|
ldmgtia r1!, {r3, r4, ip, lr} @ 4
|
|
bgt 1b @ 1
|
|
PLD( ldmeqia r1!, {r3, r4, ip, lr} )
|
|
PLD( beq 2b )
|
|
ldmfd sp!, {r4, pc} @ 3
|
|
ENDPROC(copy_page)
|