mirror of
https://github.com/edk2-porting/linux-next.git
synced 2024-12-27 14:43:58 +08:00
b24413180f
Many source files in the tree are missing licensing information, which makes it harder for compliance tools to determine the correct license. By default all files without license information are under the default license of the kernel, which is GPL version 2. Update the files which contain no license information with the 'GPL-2.0' SPDX license identifier. The SPDX identifier is a legally binding shorthand, which can be used instead of the full boiler plate text. This patch is based on work done by Thomas Gleixner and Kate Stewart and Philippe Ombredanne. How this work was done: Patches were generated and checked against linux-4.14-rc6 for a subset of the use cases: - file had no licensing information it it. - file was a */uapi/* one with no licensing information in it, - file was a */uapi/* one with existing licensing information, Further patches will be generated in subsequent months to fix up cases where non-standard license headers were used, and references to license had to be inferred by heuristics based on keywords. The analysis to determine which SPDX License Identifier to be applied to a file was done in a spreadsheet of side by side results from of the output of two independent scanners (ScanCode & Windriver) producing SPDX tag:value files created by Philippe Ombredanne. Philippe prepared the base worksheet, and did an initial spot review of a few 1000 files. The 4.13 kernel was the starting point of the analysis with 60,537 files assessed. Kate Stewart did a file by file comparison of the scanner results in the spreadsheet to determine which SPDX license identifier(s) to be applied to the file. She confirmed any determination that was not immediately clear with lawyers working with the Linux Foundation. Criteria used to select files for SPDX license identifier tagging was: - Files considered eligible had to be source code files. - Make and config files were included as candidates if they contained >5 lines of source - File already had some variant of a license header in it (even if <5 lines). All documentation files were explicitly excluded. The following heuristics were used to determine which SPDX license identifiers to apply. - when both scanners couldn't find any license traces, file was considered to have no license information in it, and the top level COPYING file license applied. For non */uapi/* files that summary was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 11139 and resulted in the first patch in this series. If that file was a */uapi/* path one, it was "GPL-2.0 WITH Linux-syscall-note" otherwise it was "GPL-2.0". Results of that was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 WITH Linux-syscall-note 930 and resulted in the second patch in this series. - if a file had some form of licensing information in it, and was one of the */uapi/* ones, it was denoted with the Linux-syscall-note if any GPL family license was found in the file or had no licensing in it (per prior point). Results summary: SPDX license identifier # files ---------------------------------------------------|------ GPL-2.0 WITH Linux-syscall-note 270 GPL-2.0+ WITH Linux-syscall-note 169 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-2-Clause) 21 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-3-Clause) 17 LGPL-2.1+ WITH Linux-syscall-note 15 GPL-1.0+ WITH Linux-syscall-note 14 ((GPL-2.0+ WITH Linux-syscall-note) OR BSD-3-Clause) 5 LGPL-2.0+ WITH Linux-syscall-note 4 LGPL-2.1 WITH Linux-syscall-note 3 ((GPL-2.0 WITH Linux-syscall-note) OR MIT) 3 ((GPL-2.0 WITH Linux-syscall-note) AND MIT) 1 and that resulted in the third patch in this series. - when the two scanners agreed on the detected license(s), that became the concluded license(s). - when there was disagreement between the two scanners (one detected a license but the other didn't, or they both detected different licenses) a manual inspection of the file occurred. - In most cases a manual inspection of the information in the file resulted in a clear resolution of the license that should apply (and which scanner probably needed to revisit its heuristics). - When it was not immediately clear, the license identifier was confirmed with lawyers working with the Linux Foundation. - If there was any question as to the appropriate license identifier, the file was flagged for further research and to be revisited later in time. In total, over 70 hours of logged manual review was done on the spreadsheet to determine the SPDX license identifiers to apply to the source files by Kate, Philippe, Thomas and, in some cases, confirmation by lawyers working with the Linux Foundation. Kate also obtained a third independent scan of the 4.13 code base from FOSSology, and compared selected files where the other two scanners disagreed against that SPDX file, to see if there was new insights. The Windriver scanner is based on an older version of FOSSology in part, so they are related. Thomas did random spot checks in about 500 files from the spreadsheets for the uapi headers and agreed with SPDX license identifier in the files he inspected. For the non-uapi files Thomas did random spot checks in about 15000 files. In initial set of patches against 4.14-rc6, 3 files were found to have copy/paste license identifier errors, and have been fixed to reflect the correct identifier. Additionally Philippe spent 10 hours this week doing a detailed manual inspection and review of the 12,461 patched files from the initial patch version early this week with: - a full scancode scan run, collecting the matched texts, detected license ids and scores - reviewing anything where there was a license detected (about 500+ files) to ensure that the applied SPDX license was correct - reviewing anything where there was no detection but the patch license was not GPL-2.0 WITH Linux-syscall-note to ensure that the applied SPDX license was correct This produced a worksheet with 20 files needing minor correction. This worksheet was then exported into 3 different .csv files for the different types of files to be modified. These .csv files were then reviewed by Greg. Thomas wrote a script to parse the csv files and add the proper SPDX tag to the file, in the format that the file expected. This script was further refined by Greg based on the output to detect more types of files automatically and to distinguish between header and source .c files (which need different comment types.) Finally Greg ran the script using the .csv files to generate the patches. Reviewed-by: Kate Stewart <kstewart@linuxfoundation.org> Reviewed-by: Philippe Ombredanne <pombredanne@nexb.com> Reviewed-by: Thomas Gleixner <tglx@linutronix.de> Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
208 lines
6.1 KiB
ArmAsm
208 lines
6.1 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
.file "wm_shrx.S"
|
|
/*---------------------------------------------------------------------------+
|
|
| wm_shrx.S |
|
|
| |
|
|
| 64 bit right shift functions |
|
|
| |
|
|
| Copyright (C) 1992,1995 |
|
|
| W. Metzenthen, 22 Parker St, Ormond, Vic 3163, |
|
|
| Australia. E-mail billm@jacobi.maths.monash.edu.au |
|
|
| |
|
|
| Call from C as: |
|
|
| unsigned FPU_shrx(void *arg1, unsigned arg2) |
|
|
| and |
|
|
| unsigned FPU_shrxs(void *arg1, unsigned arg2) |
|
|
| |
|
|
+---------------------------------------------------------------------------*/
|
|
|
|
#include "fpu_emu.h"
|
|
|
|
.text
|
|
/*---------------------------------------------------------------------------+
|
|
| unsigned FPU_shrx(void *arg1, unsigned arg2) |
|
|
| |
|
|
| Extended shift right function. |
|
|
| Fastest for small shifts. |
|
|
| Shifts the 64 bit quantity pointed to by the first arg (arg1) |
|
|
| right by the number of bits specified by the second arg (arg2). |
|
|
| Forms a 96 bit quantity from the 64 bit arg and eax: |
|
|
| [ 64 bit arg ][ eax ] |
|
|
| shift right ---------> |
|
|
| The eax register is initialized to 0 before the shifting. |
|
|
| Results returned in the 64 bit arg and eax. |
|
|
+---------------------------------------------------------------------------*/
|
|
|
|
ENTRY(FPU_shrx)
|
|
push %ebp
|
|
movl %esp,%ebp
|
|
pushl %esi
|
|
movl PARAM2,%ecx
|
|
movl PARAM1,%esi
|
|
cmpl $32,%ecx /* shrd only works for 0..31 bits */
|
|
jnc L_more_than_31
|
|
|
|
/* less than 32 bits */
|
|
pushl %ebx
|
|
movl (%esi),%ebx /* lsl */
|
|
movl 4(%esi),%edx /* msl */
|
|
xorl %eax,%eax /* extension */
|
|
shrd %cl,%ebx,%eax
|
|
shrd %cl,%edx,%ebx
|
|
shr %cl,%edx
|
|
movl %ebx,(%esi)
|
|
movl %edx,4(%esi)
|
|
popl %ebx
|
|
popl %esi
|
|
leave
|
|
ret
|
|
|
|
L_more_than_31:
|
|
cmpl $64,%ecx
|
|
jnc L_more_than_63
|
|
|
|
subb $32,%cl
|
|
movl (%esi),%eax /* lsl */
|
|
movl 4(%esi),%edx /* msl */
|
|
shrd %cl,%edx,%eax
|
|
shr %cl,%edx
|
|
movl %edx,(%esi)
|
|
movl $0,4(%esi)
|
|
popl %esi
|
|
leave
|
|
ret
|
|
|
|
L_more_than_63:
|
|
cmpl $96,%ecx
|
|
jnc L_more_than_95
|
|
|
|
subb $64,%cl
|
|
movl 4(%esi),%eax /* msl */
|
|
shr %cl,%eax
|
|
xorl %edx,%edx
|
|
movl %edx,(%esi)
|
|
movl %edx,4(%esi)
|
|
popl %esi
|
|
leave
|
|
ret
|
|
|
|
L_more_than_95:
|
|
xorl %eax,%eax
|
|
movl %eax,(%esi)
|
|
movl %eax,4(%esi)
|
|
popl %esi
|
|
leave
|
|
ret
|
|
ENDPROC(FPU_shrx)
|
|
|
|
|
|
/*---------------------------------------------------------------------------+
|
|
| unsigned FPU_shrxs(void *arg1, unsigned arg2) |
|
|
| |
|
|
| Extended shift right function (optimized for small floating point |
|
|
| integers). |
|
|
| Shifts the 64 bit quantity pointed to by the first arg (arg1) |
|
|
| right by the number of bits specified by the second arg (arg2). |
|
|
| Forms a 96 bit quantity from the 64 bit arg and eax: |
|
|
| [ 64 bit arg ][ eax ] |
|
|
| shift right ---------> |
|
|
| The eax register is initialized to 0 before the shifting. |
|
|
| The lower 8 bits of eax are lost and replaced by a flag which is |
|
|
| set (to 0x01) if any bit, apart from the first one, is set in the |
|
|
| part which has been shifted out of the arg. |
|
|
| Results returned in the 64 bit arg and eax. |
|
|
+---------------------------------------------------------------------------*/
|
|
ENTRY(FPU_shrxs)
|
|
push %ebp
|
|
movl %esp,%ebp
|
|
pushl %esi
|
|
pushl %ebx
|
|
movl PARAM2,%ecx
|
|
movl PARAM1,%esi
|
|
cmpl $64,%ecx /* shrd only works for 0..31 bits */
|
|
jnc Ls_more_than_63
|
|
|
|
cmpl $32,%ecx /* shrd only works for 0..31 bits */
|
|
jc Ls_less_than_32
|
|
|
|
/* We got here without jumps by assuming that the most common requirement
|
|
is for small integers */
|
|
/* Shift by [32..63] bits */
|
|
subb $32,%cl
|
|
movl (%esi),%eax /* lsl */
|
|
movl 4(%esi),%edx /* msl */
|
|
xorl %ebx,%ebx
|
|
shrd %cl,%eax,%ebx
|
|
shrd %cl,%edx,%eax
|
|
shr %cl,%edx
|
|
orl %ebx,%ebx /* test these 32 bits */
|
|
setne %bl
|
|
test $0x7fffffff,%eax /* and 31 bits here */
|
|
setne %bh
|
|
orw %bx,%bx /* Any of the 63 bit set ? */
|
|
setne %al
|
|
movl %edx,(%esi)
|
|
movl $0,4(%esi)
|
|
popl %ebx
|
|
popl %esi
|
|
leave
|
|
ret
|
|
|
|
/* Shift by [0..31] bits */
|
|
Ls_less_than_32:
|
|
movl (%esi),%ebx /* lsl */
|
|
movl 4(%esi),%edx /* msl */
|
|
xorl %eax,%eax /* extension */
|
|
shrd %cl,%ebx,%eax
|
|
shrd %cl,%edx,%ebx
|
|
shr %cl,%edx
|
|
test $0x7fffffff,%eax /* only need to look at eax here */
|
|
setne %al
|
|
movl %ebx,(%esi)
|
|
movl %edx,4(%esi)
|
|
popl %ebx
|
|
popl %esi
|
|
leave
|
|
ret
|
|
|
|
/* Shift by [64..95] bits */
|
|
Ls_more_than_63:
|
|
cmpl $96,%ecx
|
|
jnc Ls_more_than_95
|
|
|
|
subb $64,%cl
|
|
movl (%esi),%ebx /* lsl */
|
|
movl 4(%esi),%eax /* msl */
|
|
xorl %edx,%edx /* extension */
|
|
shrd %cl,%ebx,%edx
|
|
shrd %cl,%eax,%ebx
|
|
shr %cl,%eax
|
|
orl %ebx,%edx
|
|
setne %bl
|
|
test $0x7fffffff,%eax /* only need to look at eax here */
|
|
setne %bh
|
|
orw %bx,%bx
|
|
setne %al
|
|
xorl %edx,%edx
|
|
movl %edx,(%esi) /* set to zero */
|
|
movl %edx,4(%esi) /* set to zero */
|
|
popl %ebx
|
|
popl %esi
|
|
leave
|
|
ret
|
|
|
|
Ls_more_than_95:
|
|
/* Shift by [96..inf) bits */
|
|
xorl %eax,%eax
|
|
movl (%esi),%ebx
|
|
orl 4(%esi),%ebx
|
|
setne %al
|
|
xorl %ebx,%ebx
|
|
movl %ebx,(%esi)
|
|
movl %ebx,4(%esi)
|
|
popl %ebx
|
|
popl %esi
|
|
leave
|
|
ret
|
|
ENDPROC(FPU_shrxs)
|