mirror of
https://github.com/php/php-src.git
synced 2024-12-25 09:49:08 +08:00
caea088ac7
With recent transition to pkg-config/pkgconf this macro has been now a simple wrapper for PKG_CHECK_MODULES and PHP_EVAL_INCLINE so it's better to omit it altogether and use these two in the *.m4 code directly.
45 lines
1.3 KiB
Plaintext
45 lines
1.3 KiB
Plaintext
dnl config.m4 for extension openssl
|
|
|
|
PHP_ARG_WITH([openssl],
|
|
[for OpenSSL support],
|
|
[AS_HELP_STRING([--with-openssl],
|
|
[Include OpenSSL support (requires OpenSSL >= 1.0.1)])])
|
|
|
|
PHP_ARG_WITH([kerberos],
|
|
[for Kerberos support],
|
|
[AS_HELP_STRING([--with-kerberos],
|
|
[OPENSSL: Include Kerberos support])],
|
|
[no],
|
|
[no])
|
|
|
|
PHP_ARG_WITH([system-ciphers],
|
|
[whether to use system default cipher list instead of hardcoded value],
|
|
[AS_HELP_STRING([--with-system-ciphers],
|
|
[OPENSSL: Use system default cipher list instead of hardcoded value])],
|
|
[no],
|
|
[no])
|
|
|
|
if test "$PHP_OPENSSL" != "no"; then
|
|
PHP_NEW_EXTENSION(openssl, openssl.c xp_ssl.c, $ext_shared)
|
|
PHP_SUBST(OPENSSL_SHARED_LIBADD)
|
|
|
|
if test "$PHP_KERBEROS" != "no"; then
|
|
PKG_CHECK_MODULES([KERBEROS], [krb5-gssapi krb5])
|
|
|
|
PHP_EVAL_INCLINE($KERBEROS_CFLAGS)
|
|
PHP_EVAL_LIBLINE($KERBEROS_LIBS, OPENSSL_SHARED_LIBADD)
|
|
fi
|
|
|
|
AC_CHECK_FUNCS([RAND_egd])
|
|
|
|
PHP_SETUP_OPENSSL(OPENSSL_SHARED_LIBADD,
|
|
[
|
|
AC_DEFINE(HAVE_OPENSSL_EXT,1,[ ])
|
|
], [
|
|
AC_MSG_ERROR([OpenSSL check failed. Please check config.log for more information.])
|
|
])
|
|
if test "$PHP_SYSTEM_CIPHERS" != "no"; then
|
|
AC_DEFINE(USE_OPENSSL_SYSTEM_CIPHERS,1,[ Use system default cipher list instead of hardcoded value ])
|
|
fi
|
|
fi
|