mirror of
https://github.com/php/php-src.git
synced 2024-11-23 18:04:36 +08:00
9a3c8e51e3
Removed unused checks: - mbsinit check removed, HAVE_MBSINIT removed (not used in php-src) - mempcpy check removed, HAVE_MEMPCPY removed (not used in php-src anymore since560ed89bfbwhich uses PHP's own implementation) - strpncpy check removed, added viaa8c9e893b6and not used. - setpgid check removed since HAVE_SETPGID is not used Moved to a central configure.ac: - fpclass - mbrlen moved to configure.ac (since the HAVE_MBRLEN is used accross the php-src) - sigprocmask - getcwd - getwd - glob - strfmon - nice Duplicated checks removed: - gethostname - getlogin - getpwuid_r - socketpair - mprotect check simplified
50 lines
1.5 KiB
Plaintext
50 lines
1.5 KiB
Plaintext
PHP_ARG_ENABLE([posix],
|
|
[whether to enable POSIX-like functions],
|
|
[AS_HELP_STRING([--disable-posix],
|
|
[Disable POSIX-like functions])],
|
|
[yes])
|
|
|
|
if test "$PHP_POSIX" = "yes"; then
|
|
AC_DEFINE(HAVE_POSIX, 1, [whether to include POSIX-like functions])
|
|
PHP_NEW_EXTENSION(posix, posix.c, $ext_shared,, -DZEND_ENABLE_STATIC_TSRMLS_CACHE=1)
|
|
|
|
AC_CHECK_HEADERS([sys/mkdev.h sys/sysmacros.h])
|
|
|
|
AC_CHECK_FUNCS(seteuid setegid setsid getsid getpgid ctermid mkfifo mknod setrlimit getrlimit getgroups makedev initgroups getgrgid_r)
|
|
|
|
AC_MSG_CHECKING([for working ttyname_r() implementation])
|
|
AC_RUN_IFELSE([AC_LANG_SOURCE([[
|
|
#include <unistd.h>
|
|
|
|
int main(int argc, char *argv[])
|
|
{
|
|
char buf[64];
|
|
|
|
return !ttyname_r(0, buf, 64);
|
|
}
|
|
]])],[
|
|
AC_MSG_RESULT([yes])
|
|
AC_DEFINE(HAVE_TTYNAME_R, 1, [Whether you have a working ttyname_r])
|
|
],[
|
|
AC_MSG_RESULT([no, posix_ttyname() will be thread-unsafe])
|
|
], [
|
|
AC_MSG_RESULT([no, cannot detect working ttyname_r() when cross compiling. posix_ttyname() will be thread-unsafe])
|
|
])
|
|
|
|
AC_CACHE_CHECK([for utsname.domainname], ac_cv_have_utsname_domainname, [
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#define _GNU_SOURCE
|
|
#include <sys/utsname.h>
|
|
]],[[
|
|
return sizeof(((struct utsname *)0)->domainname);
|
|
]])],[
|
|
ac_cv_have_utsname_domainname=yes
|
|
],[
|
|
ac_cv_have_utsname_domainname=no
|
|
])
|
|
])
|
|
if test "$ac_cv_have_utsname_domainname" = yes; then
|
|
AC_DEFINE(HAVE_UTSNAME_DOMAINNAME, 1, [Whether struct utsname has domainname])
|
|
fi
|
|
fi
|