gcc/libstdc++-v3/configure.in

# Process this file with autoconf to produce a configure script, like so:
# aclocal, autoconf, autoheader, automake

AC_PREREQ(2.13)
AC_INIT(src/complex.cc)
AC_CONFIG_AUX_DIR(..)

# Gets and sets build, host, target, *_vendor, *_cpu, *_os, etc.
AC_CANONICAL_SYSTEM

# We use these options to decide which functions to include.
AC_ARG_WITH(target-subdir,
[  --with-target-subdir=SUBDIR
                           configuring in a subdirectory])
AC_ARG_WITH(cross-host,
[  --with-cross-host=HOST  configuring with a cross compiler])

# Runs configure.host and configure.target. Have to run this before
# the GLIBCPP_ENABLE_* macros below.
GLIBCPP_CONFIGURE(.)

AC_LIBTOOL_DLOPEN
AM_PROG_LIBTOOL
AC_SUBST(enable_shared)
AC_SUBST(enable_static)
GLIBCPP_CHECK_GNU_MAKE
  if test "x$_cv_gnu_make_command" = "x"; then
    AC_MSG_ERROR([GNU make not found. Please install it or correct your path.])
  fi
AM_CONFIG_HEADER(config.h)

# Check for c++ or library specific bits that don't require linking.
GLIBCPP_CHECK_COMPILER_VERSION

# Enable all the crazy c++ stuff.  C_MBCHAR must come early.
GLIBCPP_ENABLE_DEBUG($USE_MAINTAINER_MODE)
GLIBCPP_ENABLE_CSTDIO
GLIBCPP_ENABLE_C_MBCHAR([yes])
GLIBCPP_ENABLE_LONG_LONG([yes])
GLIBCPP_ENABLE_SHADOW([no])
GLIBCPP_ENABLE_THREADS
GLIBCPP_ENABLE_ATOMICITY
GLIBCPP_ENABLE_CXX_FLAGS([none])


if test -n "$with_cross_host"; then

  # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
  # may not work correctly, because the compiler may not be able to
  # link executables.

  xcompiling=1
  NATIVE=no
  # If Canadian cross, then don't pick up tools from the build
  # directory.
  if test "$build" != "$with_cross_host"; then
    CANADIAN=yes
    NULL_TARGET=yes
  else
    CANADIAN=no
    NULL_TARGET=no
  fi

  case "$target_alias" in
    *-wince-*)
	# Configure for Microsoft Windows CE, or whatever they are
	# currently calling it.
	AC_DEFINE(HAVE_FLOAT_H)

	AC_DEFINE(HAVE__FINITE)
	AC_DEFINE(HAVE__ISNAN)
	AC_DEFINE(HAVE__COPYSIGN)
	AC_DEFINE(HAVE__FPCLASS)
	AC_DEFINE(HAVE_MODF)

	ctype_include_dir="config/os/wince"
	AC_LINK_FILES($ctype_include_dir/bits/ctype_base.h, 
	include/bits/ctype_base.h)
	AC_LINK_FILES($ctype_include_dir/bits/ctype_inline.h, \
	include/bits/ctype_inline.h)
	AC_LINK_FILES($ctype_include_dir/bits/ctype_noninline.h, \
	include/bits/ctype_noninline.h)

	AC_DEFINE(_GLIBCPP_BUGGY_FLOAT_COMPLEX)
	AC_DEFINE(_GLIBCPP_BUGGY_COMPLEX)
	;;
    *)
	# We assume newlib.  This lets us hard-code the functions we know
	# we'll have.
	AC_DEFINE(HAVE_FINITE)
	AC_DEFINE(HAVE_ISNAN)
	AC_DEFINE(HAVE_ISNANF)
	AC_DEFINE(HAVE_ISINF)
	AC_DEFINE(HAVE_ISINFF)

	ctype_include_dir="config/os/newlib"
	AC_LINK_FILES($ctype_include_dir/bits/ctype_base.h, 
	include/bits/ctype_base.h)
	AC_LINK_FILES($ctype_include_dir/bits/ctype_inline.h, \
	include/bits/ctype_inline.h)
	AC_LINK_FILES($ctype_include_dir/bits/ctype_noninline.h, \
	include/bits/ctype_noninline.h)

	AC_DEFINE(_GLIBCPP_BUGGY_FLOAT_COMPLEX)
	AC_DEFINE(_GLIBCPP_BUGGY_COMPLEX)
	# need to check for faster f versions of math functions, ie sinf?
	;;
  esac
else

  # We are being configured natively. We can do more elaborate tests
  # that include AC_TRY_COMPILE now, as the linker is assumed to be
  # working.

  xcompiling=0
  NATIVE=yes
  CANADIAN=no
  NULL_TARGET=no

  # Check for available headers.
  AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
  machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h])

  GLIBCPP_CHECK_COMPILER_FEATURES
  GLIBCPP_CHECK_LINKER_FEATURES
  GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
  GLIBCPP_CHECK_MATH_SUPPORT
  GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
  GLIBCPP_CHECK_COMPLEX_MATH_COMPILER_SUPPORT
  GLIBCPP_CHECK_WCHAR_T_SUPPORT
  GLIBCPP_CHECK_CTYPE_SUPPORT
  GLIBCPP_CHECK_STDLIB_SUPPORT

  AC_FUNC_MMAP
fi

AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 
AC_CACHE_SAVE
AC_LC_MESSAGES

if test "${multilib}" = "yes"; then
  multilib_arg="--enable-multilib"
else
  multilib_arg=
fi


# Generate the various Makefiles, include files, and scripts.

# This helps subvert libstdcxx_interface, as calculated by devo/config.if
# Needed so that g++ can find the correct include subdir automatically.
INTERFACE=v3

# Check for the interface version number for specifying where header
# files are installed, if a version number is provided.
AC_MSG_CHECKING([for interface version number])
libstdcxx_interface=$INTERFACE
AC_MSG_RESULT($libstdcxx_interface)
AC_SUBST(libstdcxx_interface)

# Process the option --with-gxx-include-dir=<path to include-files directory>
AC_MSG_CHECKING([for --with-gxx-include-dir])
AC_ARG_WITH(gxx-include-dir,
[ --with-gxx-include-dir  the installation directory for include files],
[case "${withval}" in
  yes)
    AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
    gxx_include_dir=no
    ;;
  no)
    gxx_include_dir=no
    ;;
  *)
    gxx_include_dir=${withval}
    ;;
esac], [gxx_include_dir=no])
AC_MSG_RESULT($gxx_include_dir)
AC_SUBST(gxx_include_dir)
AM_CONDITIONAL(GXX_INCLUDE_DIR, test x${gxx_include_dir} != xno)

# Process the option "--enable-version-specific-runtime-libs"
AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
AC_ARG_ENABLE(version-specific-runtime-libs,
[  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
[  version_specific_libs=yes
# Need the gcc compiler version to know where to install libraries
# and header files if --enable-version-specific-runtime-libs option
# is selected.
changequote(,)dnl
gcc_tmp=`grep version_string ${srcdir}/../gcc/version.c | awk '{print $6}'`
gcc_num=`echo ${gcc_tmp} | sed 's/\"//g'`
#gcc_date=`grep version_string ${srcdir}/../gcc/version.c | awk '{print $7}'`
#gcc_version=$gcc_num-$gcc_date
gcc_version=$gcc_num
changequote([,])dnl
AC_SUBST(gcc_version)
],version_specific_libs=no)
AC_MSG_RESULT($version_specific_libs)
if test x${version_specific_libs} = xyes; then
  AM_CONDITIONAL(VERSION_SPECIFIC_LIBS, test x${version_specific_libs} = xyes)
  AC_MSG_WARN(version specific directory is: $gcc_version)
fi



# Export all the include and flag information to makefiles.
GLIBCPP_EXPORT_INCLUDES
GLIBCPP_EXPORT_FLAGS

# This should be done by mkincludedir, but hack around it now.
blddir=`pwd`
echo "checking for $blddir/include"

if test ! -d "$blddir/include"; then
  mkdir "$blddir/include"
fi

# NB: Multilibs need MULTISUBDIR defined correctly in src/Makefile.am
# so that multilib installs will end up installed in the correct
# place. To work around this not being passed down from config-ml.in
# -> top_srcdir/Makefile.am -> top_srcdir/src/Makefile.am, manually
# append it here.
AC_OUTPUT(tests_flags mkcheck Makefile src/Makefile libmath/Makefile libio/Makefile libsupc++/Makefile,
[if test -n "$CONFIG_FILES"; then
  ac_file=Makefile . ${glibcpp_basedir}/../config-ml.in
  grep '^MULTISUBDIR =' Makefile >> src/Makefile
fi
chmod +x tests_flags
chmod +x mkcheck
],
srcdir=${srcdir}
host=${host}
target=${target}
with_multisubdir=${with_multisubdir}
ac_configure_args="${multilib_arg} ${ac_configure_args}"
CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
glibcpp_basedir=${glibcpp_basedir}
CC="${CC}"
CXX="${CXX}"
)


# Generate bits/c++config.h
# NB: This must be the first generated file as others include it. . .
$srcdir/mkc++config $blddir $srcdir

# Generate bits/std_limits.h and src/limitsMEMBERS.cc
if test ! -f stamp-limits; then
  $srcdir/mknumeric_limits $blddir $srcdir $xcompiling
  touch stamp-limits
fi


# Sanity checking & User-visible messages.
# Checks down here, otherwise they get scrolled off before
# the user will notice.

# Trying to get more people to read documentation.  Possibly remove
# check and warn all the time. There is no "informational" AC_MSG_
# macro, so these are going to be printed even when --quiet/--silent
# is given.
if test ! -f stamp-sanity-warned; then
  touch stamp-sanity-warned
  echo ""
  echo "Please make certain that you read the installation information here:"
  echo "  faster => ${srcdir}/docs/install.html"
  echo "  slower => <URL:http://sources.redhat.com/libstdc++/install.html>"
  echo ""
  echo "and the configuration information here:"
  echo "  faster => ${srcdir}/docs/configopts.html"
  echo "  slower => <URL:http://sources.redhat.com/libstdc++/configopts.html>"
  echo ""
  echo "before proceeding with ${_cv_gnu_make_command}."
  echo ""
fi