mirror of
https://github.com/coreutils/coreutils.git
synced 2024-11-24 10:23:31 +08:00
72 lines
2.6 KiB
Plaintext
72 lines
2.6 KiB
Plaintext
# stat-prog.m4 serial 2
|
|
# Record the prerequisites of src/stat.c from the coreutils package.
|
|
|
|
# Copyright (C) 2002, 2003, 2004 Free Software Foundation, Inc.
|
|
|
|
# This program is free software; you can redistribute it and/or modify
|
|
# it under the terms of the GNU General Public License as published by
|
|
# the Free Software Foundation; either version 2, or (at your option)
|
|
# any later version.
|
|
|
|
# This program is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
# GNU General Public License for more details.
|
|
|
|
# You should have received a copy of the GNU General Public License
|
|
# along with this program; if not, write to the Free Software Foundation,
|
|
# Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
|
|
|
|
# Written by Jim Meyering.
|
|
|
|
AC_DEFUN([cu_PREREQ_STAT_PROG],
|
|
[
|
|
AC_CHECK_HEADERS_ONCE(sys/param.h sys/sysmacros.h sys/statvfs.h sys/vfs.h)
|
|
AC_CHECK_HEADERS(sys/mount.h, [], [],
|
|
[AC_INCLUDES_DEFAULT
|
|
[#if HAVE_SYS_PARAM_H
|
|
#include <sys/param.h>
|
|
#endif]])
|
|
AC_CHECK_FUNCS_ONCE(statvfs)
|
|
|
|
# For `struct statfs' on Ultrix 4.4.
|
|
AC_CHECK_HEADERS([netinet/in.h nfs/nfs_clnt.h nfs/vfs.h],,,
|
|
[AC_INCLUDES_DEFAULT])
|
|
|
|
AC_REQUIRE([gl_AC_TYPE_LONG_LONG])
|
|
AC_REQUIRE([gt_HEADER_INTTYPES_H])
|
|
|
|
statxfs_includes="\
|
|
$ac_includes_default
|
|
#if HAVE_SYS_STATVFS_H
|
|
# include <sys/statvfs.h>
|
|
#endif
|
|
#if HAVE_SYS_VFS_H
|
|
# include <sys/vfs.h>
|
|
#endif
|
|
#if !HAVE_SYS_STATVFS_H && !HAVE_SYS_VFS_H
|
|
# if HAVE_SYS_MOUNT_H && HAVE_SYS_PARAM_H
|
|
/* NetBSD 1.5.2 needs these, for the declaration of struct statfs. */
|
|
# include <sys/param.h>
|
|
# include <sys/mount.h>
|
|
# elif HAVE_NETINET_IN_H && HAVE_NFS_NFS_CLNT_H && HAVE_NFS_VFS_H
|
|
/* Ultrix 4.4 needs these for the declaration of struct statfs. */
|
|
# include <netinet/in.h>
|
|
# include <nfs/nfs_clnt.h>
|
|
# include <nfs/vfs.h>
|
|
# endif
|
|
#endif
|
|
"
|
|
AC_CHECK_MEMBERS([struct statfs.f_basetype],,,[$statxfs_includes])
|
|
AC_CHECK_MEMBERS([struct statvfs.f_basetype],,,[$statxfs_includes])
|
|
AC_CHECK_MEMBERS([struct statfs.f_fstypename],,,[$statxfs_includes])
|
|
AC_CHECK_MEMBERS([struct statfs.f_type],,,[$statxfs_includes])
|
|
AC_CHECK_MEMBERS([struct statvfs.f_type],,,[$statxfs_includes])
|
|
AC_CHECK_MEMBERS([struct statfs.f_fsid.__val],,,[$statxfs_includes])
|
|
AC_CHECK_MEMBERS([struct statvfs.f_fsid.__val],,,[$statxfs_includes])
|
|
AC_CHECK_MEMBERS([struct statfs.f_namemax],,,[$statxfs_includes])
|
|
AC_CHECK_MEMBERS([struct statvfs.f_namemax],,,[$statxfs_includes])
|
|
AC_CHECK_MEMBERS([struct statfs.f_namelen],,,[$statxfs_includes])
|
|
AC_CHECK_MEMBERS([struct statvfs.f_namelen],,,[$statxfs_includes])
|
|
])
|