mirror of
https://github.com/FreeRDP/FreeRDP.git
synced 2024-11-27 03:44:06 +08:00
cmake: fixed compatibility with version 2.8.0
* enable_cmake_compat to enable compatibility for specific cmake versions * added required files for 2.8.2 and 2.8.6 (taken from a recent cmake version)
This commit is contained in:
Bernhard Miklautz
parent
d81c0be0b9
commit
7d6f012097
@ -24,6 +24,12 @@ project(FreeRDP C)
|
||||
|
||||
set(CMAKE_COLOR_MAKEFILE ON)
|
||||
|
||||
# Include our extra modules
|
||||
set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/)
|
||||
|
||||
# Check for cmake compatibility (enable/disable features)
|
||||
include(CheckCmakeCompat)
|
||||
|
||||
# Include cmake modules
|
||||
include(CheckIncludeFiles)
|
||||
include(CheckLibraryExists)
|
||||
@ -32,12 +38,6 @@ include(CMakeDetermineSystem)
|
||||
include(FindPkgConfig)
|
||||
include(TestBigEndian)
|
||||
|
||||
# Include our extra modules
|
||||
set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/)
|
||||
|
||||
# Check for cmake compatibility (enable/disable features)
|
||||
include(CheckCmakeCompat)
|
||||
|
||||
include(FindFeature)
|
||||
include(AutoVersioning)
|
||||
include(ConfigOptions)
|
||||
|
||||
@ -16,10 +16,16 @@
|
||||
# limitations under the License.
|
||||
#=============================================================================
|
||||
|
||||
# Enable compatibility for cmake < 2.8.3
|
||||
if(${CMAKE_VERSION} VERSION_LESS 2.8.3)
|
||||
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_SOURCE_DIR}/cmake/compat_2.8.3/)
|
||||
endif()
|
||||
macro(enable_cmake_compat CMVERSION)
|
||||
if(${CMAKE_VERSION} VERSION_LESS ${CMVERSION})
|
||||
LIST(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/compat_${CMVERSION}/")
|
||||
endif()
|
||||
endmacro()
|
||||
|
||||
# Compatibility includes - oder does matter!
|
||||
enable_cmake_compat(2.8.6)
|
||||
enable_cmake_compat(2.8.3)
|
||||
enable_cmake_compat(2.8.2)
|
||||
|
||||
# If MONOLITHIC_BUILD is used with cmake < 2.8.8 build fails
|
||||
if (MONOLITHIC_BUILD)
|
||||
|
||||
373
cmake/compat_2.8.2/FindPkgConfig.cmake
Normal file
373
cmake/compat_2.8.2/FindPkgConfig.cmake
Normal file
@ -0,0 +1,373 @@
|
||||
# - a pkg-config module for CMake
|
||||
#
|
||||
# Usage:
|
||||
# pkg_check_modules(<PREFIX> [REQUIRED] [QUIET] <MODULE> [<MODULE>]*)
|
||||
# checks for all the given modules
|
||||
#
|
||||
# pkg_search_module(<PREFIX> [REQUIRED] [QUIET] <MODULE> [<MODULE>]*)
|
||||
# checks for given modules and uses the first working one
|
||||
#
|
||||
# When the 'REQUIRED' argument was set, macros will fail with an error
|
||||
# when module(s) could not be found
|
||||
#
|
||||
# When the 'QUIET' argument is set, no status messages will be printed.
|
||||
#
|
||||
# It sets the following variables:
|
||||
# PKG_CONFIG_FOUND ... if pkg-config executable was found
|
||||
# PKG_CONFIG_EXECUTABLE ... pathname of the pkg-config program
|
||||
# PKG_CONFIG_VERSION_STRING ... the version of the pkg-config program found
|
||||
# (since CMake 2.8.8)
|
||||
#
|
||||
# For the following variables two sets of values exist; first one is the
|
||||
# common one and has the given PREFIX. The second set contains flags
|
||||
# which are given out when pkgconfig was called with the '--static'
|
||||
# option.
|
||||
# <XPREFIX>_FOUND ... set to 1 if module(s) exist
|
||||
# <XPREFIX>_LIBRARIES ... only the libraries (w/o the '-l')
|
||||
# <XPREFIX>_LIBRARY_DIRS ... the paths of the libraries (w/o the '-L')
|
||||
# <XPREFIX>_LDFLAGS ... all required linker flags
|
||||
# <XPREFIX>_LDFLAGS_OTHER ... all other linker flags
|
||||
# <XPREFIX>_INCLUDE_DIRS ... the '-I' preprocessor flags (w/o the '-I')
|
||||
# <XPREFIX>_CFLAGS ... all required cflags
|
||||
# <XPREFIX>_CFLAGS_OTHER ... the other compiler flags
|
||||
#
|
||||
# <XPREFIX> = <PREFIX> for common case
|
||||
# <XPREFIX> = <PREFIX>_STATIC for static linking
|
||||
#
|
||||
# There are some special variables whose prefix depends on the count
|
||||
# of given modules. When there is only one module, <PREFIX> stays
|
||||
# unchanged. When there are multiple modules, the prefix will be
|
||||
# changed to <PREFIX>_<MODNAME>:
|
||||
# <XPREFIX>_VERSION ... version of the module
|
||||
# <XPREFIX>_PREFIX ... prefix-directory of the module
|
||||
# <XPREFIX>_INCLUDEDIR ... include-dir of the module
|
||||
# <XPREFIX>_LIBDIR ... lib-dir of the module
|
||||
#
|
||||
# <XPREFIX> = <PREFIX> when |MODULES| == 1, else
|
||||
# <XPREFIX> = <PREFIX>_<MODNAME>
|
||||
#
|
||||
# A <MODULE> parameter can have the following formats:
|
||||
# {MODNAME} ... matches any version
|
||||
# {MODNAME}>={VERSION} ... at least version <VERSION> is required
|
||||
# {MODNAME}={VERSION} ... exactly version <VERSION> is required
|
||||
# {MODNAME}<={VERSION} ... modules must not be newer than <VERSION>
|
||||
#
|
||||
# Examples
|
||||
# pkg_check_modules (GLIB2 glib-2.0)
|
||||
#
|
||||
# pkg_check_modules (GLIB2 glib-2.0>=2.10)
|
||||
# requires at least version 2.10 of glib2 and defines e.g.
|
||||
# GLIB2_VERSION=2.10.3
|
||||
#
|
||||
# pkg_check_modules (FOO glib-2.0>=2.10 gtk+-2.0)
|
||||
# requires both glib2 and gtk2, and defines e.g.
|
||||
# FOO_glib-2.0_VERSION=2.10.3
|
||||
# FOO_gtk+-2.0_VERSION=2.8.20
|
||||
#
|
||||
# pkg_check_modules (XRENDER REQUIRED xrender)
|
||||
# defines e.g.:
|
||||
# XRENDER_LIBRARIES=Xrender;X11
|
||||
# XRENDER_STATIC_LIBRARIES=Xrender;X11;pthread;Xau;Xdmcp
|
||||
#
|
||||
# pkg_search_module (BAR libxml-2.0 libxml2 libxml>=2)
|
||||
|
||||
#=============================================================================
|
||||
# Copyright 2006-2009 Kitware, Inc.
|
||||
# Copyright 2006 Enrico Scholz <enrico.scholz@informatik.tu-chemnitz.de>
|
||||
#
|
||||
# Distributed under the OSI-approved BSD License (the "License");
|
||||
# see accompanying file Copyright.txt for details.
|
||||
#
|
||||
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
||||
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
||||
# See the License for more information.
|
||||
#=============================================================================
|
||||
# (To distribute this file outside of CMake, substitute the full
|
||||
# License text for the above reference.)
|
||||
|
||||
### Common stuff ####
|
||||
set(PKG_CONFIG_VERSION 1)
|
||||
|
||||
find_program(PKG_CONFIG_EXECUTABLE NAMES pkg-config DOC "pkg-config executable")
|
||||
mark_as_advanced(PKG_CONFIG_EXECUTABLE)
|
||||
|
||||
if (PKG_CONFIG_EXECUTABLE)
|
||||
execute_process(COMMAND ${PKG_CONFIG_EXECUTABLE} --version
|
||||
OUTPUT_VARIABLE PKG_CONFIG_VERSION_STRING
|
||||
ERROR_QUIET
|
||||
OUTPUT_STRIP_TRAILING_WHITESPACE)
|
||||
endif ()
|
||||
|
||||
include(FindPackageHandleStandardArgs)
|
||||
find_package_handle_standard_args(PkgConfig
|
||||
REQUIRED_VARS PKG_CONFIG_EXECUTABLE
|
||||
VERSION_VAR PKG_CONFIG_VERSION_STRING)
|
||||
|
||||
# This is needed because the module name is "PkgConfig" but the name of
|
||||
# this variable has always been PKG_CONFIG_FOUND so this isn't automatically
|
||||
# handled by FPHSA.
|
||||
set(PKG_CONFIG_FOUND "${PKGCONFIG_FOUND}")
|
||||
|
||||
# Unsets the given variables
|
||||
macro(_pkgconfig_unset var)
|
||||
set(${var} "" CACHE INTERNAL "")
|
||||
endmacro()
|
||||
|
||||
macro(_pkgconfig_set var value)
|
||||
set(${var} ${value} CACHE INTERNAL "")
|
||||
endmacro()
|
||||
|
||||
# Invokes pkgconfig, cleans up the result and sets variables
|
||||
macro(_pkgconfig_invoke _pkglist _prefix _varname _regexp)
|
||||
set(_pkgconfig_invoke_result)
|
||||
|
||||
execute_process(
|
||||
COMMAND ${PKG_CONFIG_EXECUTABLE} ${ARGN} ${_pkglist}
|
||||
OUTPUT_VARIABLE _pkgconfig_invoke_result
|
||||
RESULT_VARIABLE _pkgconfig_failed)
|
||||
|
||||
if (_pkgconfig_failed)
|
||||
set(_pkgconfig_${_varname} "")
|
||||
_pkgconfig_unset(${_prefix}_${_varname})
|
||||
else()
|
||||
string(REGEX REPLACE "[\r\n]" " " _pkgconfig_invoke_result "${_pkgconfig_invoke_result}")
|
||||
string(REGEX REPLACE " +$" "" _pkgconfig_invoke_result "${_pkgconfig_invoke_result}")
|
||||
|
||||
if (NOT ${_regexp} STREQUAL "")
|
||||
string(REGEX REPLACE "${_regexp}" " " _pkgconfig_invoke_result "${_pkgconfig_invoke_result}")
|
||||
endif()
|
||||
|
||||
separate_arguments(_pkgconfig_invoke_result)
|
||||
|
||||
#message(STATUS " ${_varname} ... ${_pkgconfig_invoke_result}")
|
||||
set(_pkgconfig_${_varname} ${_pkgconfig_invoke_result})
|
||||
_pkgconfig_set(${_prefix}_${_varname} "${_pkgconfig_invoke_result}")
|
||||
endif()
|
||||
endmacro()
|
||||
|
||||
# Invokes pkgconfig two times; once without '--static' and once with
|
||||
# '--static'
|
||||
macro(_pkgconfig_invoke_dyn _pkglist _prefix _varname cleanup_regexp)
|
||||
_pkgconfig_invoke("${_pkglist}" ${_prefix} ${_varname} "${cleanup_regexp}" ${ARGN})
|
||||
_pkgconfig_invoke("${_pkglist}" ${_prefix} STATIC_${_varname} "${cleanup_regexp}" --static ${ARGN})
|
||||
endmacro()
|
||||
|
||||
# Splits given arguments into options and a package list
|
||||
macro(_pkgconfig_parse_options _result _is_req _is_silent)
|
||||
set(${_is_req} 0)
|
||||
set(${_is_silent} 0)
|
||||
|
||||
foreach(_pkg ${ARGN})
|
||||
if (_pkg STREQUAL "REQUIRED")
|
||||
set(${_is_req} 1)
|
||||
endif ()
|
||||
if (_pkg STREQUAL "QUIET")
|
||||
set(${_is_silent} 1)
|
||||
endif ()
|
||||
endforeach()
|
||||
|
||||
set(${_result} ${ARGN})
|
||||
list(REMOVE_ITEM ${_result} "REQUIRED")
|
||||
list(REMOVE_ITEM ${_result} "QUIET")
|
||||
endmacro()
|
||||
|
||||
###
|
||||
macro(_pkg_check_modules_internal _is_required _is_silent _prefix)
|
||||
_pkgconfig_unset(${_prefix}_FOUND)
|
||||
_pkgconfig_unset(${_prefix}_VERSION)
|
||||
_pkgconfig_unset(${_prefix}_PREFIX)
|
||||
_pkgconfig_unset(${_prefix}_INCLUDEDIR)
|
||||
_pkgconfig_unset(${_prefix}_LIBDIR)
|
||||
_pkgconfig_unset(${_prefix}_LIBS)
|
||||
_pkgconfig_unset(${_prefix}_LIBS_L)
|
||||
_pkgconfig_unset(${_prefix}_LIBS_PATHS)
|
||||
_pkgconfig_unset(${_prefix}_LIBS_OTHER)
|
||||
_pkgconfig_unset(${_prefix}_CFLAGS)
|
||||
_pkgconfig_unset(${_prefix}_CFLAGS_I)
|
||||
_pkgconfig_unset(${_prefix}_CFLAGS_OTHER)
|
||||
_pkgconfig_unset(${_prefix}_STATIC_LIBDIR)
|
||||
_pkgconfig_unset(${_prefix}_STATIC_LIBS)
|
||||
_pkgconfig_unset(${_prefix}_STATIC_LIBS_L)
|
||||
_pkgconfig_unset(${_prefix}_STATIC_LIBS_PATHS)
|
||||
_pkgconfig_unset(${_prefix}_STATIC_LIBS_OTHER)
|
||||
_pkgconfig_unset(${_prefix}_STATIC_CFLAGS)
|
||||
_pkgconfig_unset(${_prefix}_STATIC_CFLAGS_I)
|
||||
_pkgconfig_unset(${_prefix}_STATIC_CFLAGS_OTHER)
|
||||
|
||||
# create a better addressable variable of the modules and calculate its size
|
||||
set(_pkg_check_modules_list ${ARGN})
|
||||
list(LENGTH _pkg_check_modules_list _pkg_check_modules_cnt)
|
||||
|
||||
if(PKG_CONFIG_EXECUTABLE)
|
||||
# give out status message telling checked module
|
||||
if (NOT ${_is_silent})
|
||||
if (_pkg_check_modules_cnt EQUAL 1)
|
||||
message(STATUS "checking for module '${_pkg_check_modules_list}'")
|
||||
else()
|
||||
message(STATUS "checking for modules '${_pkg_check_modules_list}'")
|
||||
endif()
|
||||
endif()
|
||||
|
||||
set(_pkg_check_modules_packages)
|
||||
set(_pkg_check_modules_failed)
|
||||
|
||||
# iterate through module list and check whether they exist and match the required version
|
||||
foreach (_pkg_check_modules_pkg ${_pkg_check_modules_list})
|
||||
set(_pkg_check_modules_exist_query)
|
||||
|
||||
# check whether version is given
|
||||
if (_pkg_check_modules_pkg MATCHES ".*(>=|=|<=).*")
|
||||
string(REGEX REPLACE "(.*[^><])(>=|=|<=)(.*)" "\\1" _pkg_check_modules_pkg_name "${_pkg_check_modules_pkg}")
|
||||
string(REGEX REPLACE "(.*[^><])(>=|=|<=)(.*)" "\\2" _pkg_check_modules_pkg_op "${_pkg_check_modules_pkg}")
|
||||
string(REGEX REPLACE "(.*[^><])(>=|=|<=)(.*)" "\\3" _pkg_check_modules_pkg_ver "${_pkg_check_modules_pkg}")
|
||||
else()
|
||||
set(_pkg_check_modules_pkg_name "${_pkg_check_modules_pkg}")
|
||||
set(_pkg_check_modules_pkg_op)
|
||||
set(_pkg_check_modules_pkg_ver)
|
||||
endif()
|
||||
|
||||
# handle the operands
|
||||
if (_pkg_check_modules_pkg_op STREQUAL ">=")
|
||||
list(APPEND _pkg_check_modules_exist_query --atleast-version)
|
||||
endif()
|
||||
|
||||
if (_pkg_check_modules_pkg_op STREQUAL "=")
|
||||
list(APPEND _pkg_check_modules_exist_query --exact-version)
|
||||
endif()
|
||||
|
||||
if (_pkg_check_modules_pkg_op STREQUAL "<=")
|
||||
list(APPEND _pkg_check_modules_exist_query --max-version)
|
||||
endif()
|
||||
|
||||
# create the final query which is of the format:
|
||||
# * --atleast-version <version> <pkg-name>
|
||||
# * --exact-version <version> <pkg-name>
|
||||
# * --max-version <version> <pkg-name>
|
||||
# * --exists <pkg-name>
|
||||
if (_pkg_check_modules_pkg_op)
|
||||
list(APPEND _pkg_check_modules_exist_query "${_pkg_check_modules_pkg_ver}")
|
||||
else()
|
||||
list(APPEND _pkg_check_modules_exist_query --exists)
|
||||
endif()
|
||||
|
||||
_pkgconfig_unset(${_prefix}_${_pkg_check_modules_pkg_name}_VERSION)
|
||||
_pkgconfig_unset(${_prefix}_${_pkg_check_modules_pkg_name}_PREFIX)
|
||||
_pkgconfig_unset(${_prefix}_${_pkg_check_modules_pkg_name}_INCLUDEDIR)
|
||||
_pkgconfig_unset(${_prefix}_${_pkg_check_modules_pkg_name}_LIBDIR)
|
||||
|
||||
list(APPEND _pkg_check_modules_exist_query "${_pkg_check_modules_pkg_name}")
|
||||
list(APPEND _pkg_check_modules_packages "${_pkg_check_modules_pkg_name}")
|
||||
|
||||
# execute the query
|
||||
execute_process(
|
||||
COMMAND ${PKG_CONFIG_EXECUTABLE} ${_pkg_check_modules_exist_query}
|
||||
RESULT_VARIABLE _pkgconfig_retval)
|
||||
|
||||
# evaluate result and tell failures
|
||||
if (_pkgconfig_retval)
|
||||
if(NOT ${_is_silent})
|
||||
message(STATUS " package '${_pkg_check_modules_pkg}' not found")
|
||||
endif()
|
||||
|
||||
set(_pkg_check_modules_failed 1)
|
||||
endif()
|
||||
endforeach()
|
||||
|
||||
if(_pkg_check_modules_failed)
|
||||
# fail when requested
|
||||
if (${_is_required})
|
||||
message(SEND_ERROR "A required package was not found")
|
||||
endif ()
|
||||
else()
|
||||
# when we are here, we checked whether requested modules
|
||||
# exist. Now, go through them and set variables
|
||||
|
||||
_pkgconfig_set(${_prefix}_FOUND 1)
|
||||
list(LENGTH _pkg_check_modules_packages pkg_count)
|
||||
|
||||
# iterate through all modules again and set individual variables
|
||||
foreach (_pkg_check_modules_pkg ${_pkg_check_modules_packages})
|
||||
# handle case when there is only one package required
|
||||
if (pkg_count EQUAL 1)
|
||||
set(_pkg_check_prefix "${_prefix}")
|
||||
else()
|
||||
set(_pkg_check_prefix "${_prefix}_${_pkg_check_modules_pkg}")
|
||||
endif()
|
||||
|
||||
_pkgconfig_invoke(${_pkg_check_modules_pkg} "${_pkg_check_prefix}" VERSION "" --modversion )
|
||||
_pkgconfig_invoke(${_pkg_check_modules_pkg} "${_pkg_check_prefix}" PREFIX "" --variable=prefix )
|
||||
_pkgconfig_invoke(${_pkg_check_modules_pkg} "${_pkg_check_prefix}" INCLUDEDIR "" --variable=includedir )
|
||||
_pkgconfig_invoke(${_pkg_check_modules_pkg} "${_pkg_check_prefix}" LIBDIR "" --variable=libdir )
|
||||
|
||||
if (NOT ${_is_silent})
|
||||
message(STATUS " found ${_pkg_check_modules_pkg}, version ${_pkgconfig_VERSION}")
|
||||
endif ()
|
||||
endforeach()
|
||||
|
||||
# set variables which are combined for multiple modules
|
||||
_pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" LIBRARIES "(^| )-l" --libs-only-l )
|
||||
_pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" LIBRARY_DIRS "(^| )-L" --libs-only-L )
|
||||
_pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" LDFLAGS "" --libs )
|
||||
_pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" LDFLAGS_OTHER "" --libs-only-other )
|
||||
|
||||
_pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" INCLUDE_DIRS "(^| )-I" --cflags-only-I )
|
||||
_pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" CFLAGS "" --cflags )
|
||||
_pkgconfig_invoke_dyn("${_pkg_check_modules_packages}" "${_prefix}" CFLAGS_OTHER "" --cflags-only-other )
|
||||
endif()
|
||||
else()
|
||||
if (${_is_required})
|
||||
message(SEND_ERROR "pkg-config tool not found")
|
||||
endif ()
|
||||
endif()
|
||||
endmacro()
|
||||
|
||||
###
|
||||
### User visible macros start here
|
||||
###
|
||||
|
||||
###
|
||||
macro(pkg_check_modules _prefix _module0)
|
||||
# check cached value
|
||||
if (NOT DEFINED __pkg_config_checked_${_prefix} OR __pkg_config_checked_${_prefix} LESS ${PKG_CONFIG_VERSION} OR NOT ${_prefix}_FOUND)
|
||||
_pkgconfig_parse_options (_pkg_modules _pkg_is_required _pkg_is_silent "${_module0}" ${ARGN})
|
||||
_pkg_check_modules_internal("${_pkg_is_required}" "${_pkg_is_silent}" "${_prefix}" ${_pkg_modules})
|
||||
|
||||
_pkgconfig_set(__pkg_config_checked_${_prefix} ${PKG_CONFIG_VERSION})
|
||||
endif()
|
||||
endmacro()
|
||||
|
||||
###
|
||||
macro(pkg_search_module _prefix _module0)
|
||||
# check cached value
|
||||
if (NOT DEFINED __pkg_config_checked_${_prefix} OR __pkg_config_checked_${_prefix} LESS ${PKG_CONFIG_VERSION} OR NOT ${_prefix}_FOUND)
|
||||
set(_pkg_modules_found 0)
|
||||
_pkgconfig_parse_options(_pkg_modules_alt _pkg_is_required _pkg_is_silent "${_module0}" ${ARGN})
|
||||
|
||||
if (NOT ${_pkg_is_silent})
|
||||
message(STATUS "checking for one of the modules '${_pkg_modules_alt}'")
|
||||
endif ()
|
||||
|
||||
# iterate through all modules and stop at the first working one.
|
||||
foreach(_pkg_alt ${_pkg_modules_alt})
|
||||
if(NOT _pkg_modules_found)
|
||||
_pkg_check_modules_internal(0 1 "${_prefix}" "${_pkg_alt}")
|
||||
endif()
|
||||
|
||||
if (${_prefix}_FOUND)
|
||||
set(_pkg_modules_found 1)
|
||||
endif()
|
||||
endforeach()
|
||||
|
||||
if (NOT ${_prefix}_FOUND)
|
||||
if(${_pkg_is_required})
|
||||
message(SEND_ERROR "None of the required '${_pkg_modules_alt}' found")
|
||||
endif()
|
||||
endif()
|
||||
|
||||
_pkgconfig_set(__pkg_config_checked_${_prefix} ${PKG_CONFIG_VERSION})
|
||||
endif()
|
||||
endmacro()
|
||||
|
||||
### Local Variables:
|
||||
### mode: cmake
|
||||
### End:
|
||||
466
cmake/compat_2.8.6/FeatureSummary.cmake
Normal file
466
cmake/compat_2.8.6/FeatureSummary.cmake
Normal file
@ -0,0 +1,466 @@
|
||||
# - Macros for generating a summary of enabled/disabled features
|
||||
#
|
||||
# This module provides the macros feature_summary(), set_package_properties() and
|
||||
# add_feature_info().
|
||||
# For compatibility it also still provides set_package_info(), set_feature_info(),
|
||||
# print_enabled_features() and print_disabled_features().
|
||||
#
|
||||
# These macros can be used to generate a summary of enabled and disabled
|
||||
# packages and/or feature for a build tree:
|
||||
#
|
||||
# -- The following OPTIONAL packages have been found:
|
||||
# LibXml2 (required version >= 2.4) , XML processing library. , <http://xmlsoft.org>
|
||||
# * Enables HTML-import in MyWordProcessor
|
||||
# * Enables odt-export in MyWordProcessor
|
||||
# PNG , A PNG image library. , <http://www.libpng.org/pub/png/>
|
||||
# * Enables saving screenshots
|
||||
# -- The following OPTIONAL packages have not been found:
|
||||
# Lua51 , The Lua scripting language. , <http://www.lua.org>
|
||||
# * Enables macros in MyWordProcessor
|
||||
# Foo , Foo provides cool stuff.
|
||||
#
|
||||
#
|
||||
# FEATURE_SUMMARY( [FILENAME <file>]
|
||||
# [APPEND]
|
||||
# [VAR <variable_name>]
|
||||
# [INCLUDE_QUIET_PACKAGES]
|
||||
# [FATAL_ON_MISSING_REQUIRED_PACKAGES]
|
||||
# [DESCRIPTION "Found packages:"]
|
||||
# WHAT (ALL | PACKAGES_FOUND | PACKAGES_NOT_FOUND
|
||||
# | ENABLED_FEATURES | DISABLED_FEATURES]
|
||||
# )
|
||||
#
|
||||
# The FEATURE_SUMMARY() macro can be used to print information about enabled
|
||||
# or disabled packages or features of a project.
|
||||
# By default, only the names of the features/packages will be printed and their
|
||||
# required version when one was specified. Use SET_PACKAGE_PROPERTIES() to add more
|
||||
# useful information, like e.g. a download URL for the respective package or their
|
||||
# purpose in the project.
|
||||
#
|
||||
# The WHAT option is the only mandatory option. Here you specify what information
|
||||
# will be printed:
|
||||
# ALL: print everything
|
||||
# ENABLED_FEATURES: the list of all features which are enabled
|
||||
# DISABLED_FEATURES: the list of all features which are disabled
|
||||
# PACKAGES_FOUND: the list of all packages which have been found
|
||||
# PACKAGES_NOT_FOUND: the list of all packages which have not been found
|
||||
# OPTIONAL_PACKAGES_FOUND: only those packages which have been found which have the type OPTIONAL
|
||||
# OPTIONAL_PACKAGES_NOT_FOUND: only those packages which have not been found which have the type OPTIONAL
|
||||
# RECOMMENDED_PACKAGES_FOUND: only those packages which have been found which have the type RECOMMENDED
|
||||
# RECOMMENDED_PACKAGES_NOT_FOUND: only those packages which have not been found which have the type RECOMMENDED
|
||||
# REQUIRED_PACKAGES_FOUND: only those packages which have been found which have the type REQUIRED
|
||||
# REQUIRED_PACKAGES_NOT_FOUND: only those packages which have not been found which have the type REQUIRED
|
||||
# RUNTIME_PACKAGES_FOUND: only those packages which have been found which have the type RUNTIME
|
||||
# RUNTIME_PACKAGES_NOT_FOUND: only those packages which have not been found which have the type RUNTIME
|
||||
#
|
||||
# If a FILENAME is given, the information is printed into this file. If APPEND
|
||||
# is used, it is appended to this file, otherwise the file is overwritten if
|
||||
# it already existed.
|
||||
# If the VAR option is used, the information is "printed" into the specified
|
||||
# variable.
|
||||
# If FILENAME is not used, the information is printed to the terminal.
|
||||
# Using the DESCRIPTION option a description or headline can be set which will
|
||||
# be printed above the actual content.
|
||||
# If INCLUDE_QUIET_PACKAGES is given, packages which have been searched with find_package(... QUIET) will
|
||||
# also be listed. By default they are skipped.
|
||||
# If FATAL_ON_MISSING_REQUIRED_PACKAGES is given, CMake will abort if a package which is marked as REQUIRED
|
||||
# has not been found.
|
||||
#
|
||||
# Example 1, append everything to a file:
|
||||
# feature_summary(WHAT ALL
|
||||
# FILENAME ${CMAKE_BINARY_DIR}/all.log APPEND)
|
||||
#
|
||||
# Example 2, print the enabled features into the variable enabledFeaturesText, including QUIET packages:
|
||||
# feature_summary(WHAT ENABLED_FEATURES
|
||||
# INCLUDE_QUIET_PACKAGES
|
||||
# DESCRIPTION "Enabled Features:"
|
||||
# VAR enabledFeaturesText)
|
||||
# message(STATUS "${enabledFeaturesText}")
|
||||
#
|
||||
#
|
||||
# SET_PACKAGE_PROPERTIES(<name> PROPERTIES [ URL <url> ]
|
||||
# [ DESCRIPTION <description> ]
|
||||
# [ TYPE (RUNTIME|OPTIONAL|RECOMMENDED|REQUIRED) ]
|
||||
# [ PURPOSE <purpose> ]
|
||||
# )
|
||||
#
|
||||
# Use this macro to set up information about the named package, which can
|
||||
# then be displayed via FEATURE_SUMMARY().
|
||||
# This can be done either directly in the Find-module or in the project
|
||||
# which uses the module after the FIND_PACKAGE() call.
|
||||
# The features for which information can be set are added automatically by the
|
||||
# find_package() command.
|
||||
#
|
||||
# URL: this should be the homepage of the package, or something similar. Ideally this is set
|
||||
# already directly in the Find-module.
|
||||
#
|
||||
# DESCRIPTION: A short description what that package is, at most one sentence.
|
||||
# Ideally this is set already directly in the Find-module.
|
||||
#
|
||||
# TYPE: What type of dependency has the using project on that package. Default is OPTIONAL.
|
||||
# In this case it is a package which can be used by the project when available at buildtime,
|
||||
# but it also work without. RECOMMENDED is similar to OPTIONAL, i.e. the project will build
|
||||
# if the package is not present, but the functionality of the resulting binaries will be severly
|
||||
# limited. If a REQUIRED package is not available at buildtime, the project may not even build. This
|
||||
# can be combined with the FATAL_ON_MISSING_REQUIRED_PACKAGES argument for feature_summary().
|
||||
# Last, a RUNTIME package is a package which is actually not used at all during the build, but
|
||||
# which is required for actually running the resulting binaries. So if such a package is missing,
|
||||
# the project can still be built, but it may not work later on. If set_package_properties() is called
|
||||
# multiple times for the same package with different TYPEs, the TYPE is only changed to higher
|
||||
# TYPEs ( RUNTIME < OPTIONAL < RECOMMENDED < REQUIRED ), lower TYPEs are ignored.
|
||||
# The TYPE property is project-specific, so it cannot be set by the Find-module, but must be set in the project.
|
||||
#
|
||||
# PURPOSE: This describes which features this package enables in the project, i.e. it tells the user
|
||||
# what functionality he gets in the resulting binaries.
|
||||
# If set_package_properties() is called multiple times for a package, all PURPOSE properties are appended
|
||||
# to a list of purposes of the package in the project.
|
||||
# As the TYPE property, also the PURPOSE property
|
||||
# is project-specific, so it cannot be set by the Find-module, but must be set in the project.
|
||||
#
|
||||
#
|
||||
# Example for setting the info for a package:
|
||||
# find_package(LibXml2)
|
||||
# set_package_properties(LibXml2 PROPERTIES DESCRIPTION "A XML processing library."
|
||||
# URL "http://xmlsoft.org/")
|
||||
#
|
||||
# set_package_properties(LibXml2 PROPERTIES TYPE RECOMMENDED
|
||||
# PURPOSE "Enables HTML-import in MyWordProcessor")
|
||||
# ...
|
||||
# set_package_properties(LibXml2 PROPERTIES TYPE OPTIONAL
|
||||
# PURPOSE "Enables odt-export in MyWordProcessor")
|
||||
#
|
||||
# find_package(DBUS)
|
||||
# set_package_properties(DBUS PROPERTIES TYPE RUNTIME
|
||||
# PURPOSE "Necessary to disable the screensaver during a presentation" )
|
||||
#
|
||||
# ADD_FEATURE_INFO(<name> <enabled> <description>)
|
||||
# Use this macro to add information about a feature with the given <name>.
|
||||
# <enabled> contains whether this feature is enabled or not, <description>
|
||||
# is a text describing the feature.
|
||||
# The information can be displayed using feature_summary() for ENABLED_FEATURES
|
||||
# and DISABLED_FEATURES respectively.
|
||||
#
|
||||
# Example for setting the info for a feature:
|
||||
# option(WITH_FOO "Help for foo" ON)
|
||||
# add_feature_info(Foo WITH_FOO "The Foo feature provides very cool stuff.")
|
||||
#
|
||||
#
|
||||
# The following macros are provided for compatibility with previous CMake versions:
|
||||
#
|
||||
# SET_PACKAGE_INFO(<name> <description> [<url> [<purpose>] ] )
|
||||
# Use this macro to set up information about the named package, which can
|
||||
# then be displayed via FEATURE_SUMMARY().
|
||||
# This can be done either directly in the Find-module or in the project
|
||||
# which uses the module after the FIND_PACKAGE() call.
|
||||
# The features for which information can be set are added automatically by the
|
||||
# find_package() command.
|
||||
#
|
||||
# PRINT_ENABLED_FEATURES()
|
||||
# Does the same as FEATURE_SUMMARY(WHAT ENABLED_FEATURES DESCRIPTION "Enabled features:")
|
||||
#
|
||||
# PRINT_DISABLED_FEATURES()
|
||||
# Does the same as FEATURE_SUMMARY(WHAT DISABLED_FEATURES DESCRIPTION "Disabled features:")
|
||||
#
|
||||
# SET_FEATURE_INFO(<name> <description> [<url>] )
|
||||
# Does the same as SET_PACKAGE_INFO(<name> <description> <url> )
|
||||
|
||||
#=============================================================================
|
||||
# Copyright 2007-2009 Kitware, Inc.
|
||||
#
|
||||
# Distributed under the OSI-approved BSD License (the "License");
|
||||
# see accompanying file Copyright.txt for details.
|
||||
#
|
||||
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
||||
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
||||
# See the License for more information.
|
||||
#=============================================================================
|
||||
# (To distribute this file outside of CMake, substitute the full
|
||||
# License text for the above reference.)
|
||||
|
||||
INCLUDE(CMakeParseArguments)
|
||||
|
||||
|
||||
FUNCTION(ADD_FEATURE_INFO _name _enabled _desc)
|
||||
IF (${_enabled})
|
||||
SET_PROPERTY(GLOBAL APPEND PROPERTY ENABLED_FEATURES "${_name}")
|
||||
ELSE ()
|
||||
SET_PROPERTY(GLOBAL APPEND PROPERTY DISABLED_FEATURES "${_name}")
|
||||
ENDIF ()
|
||||
|
||||
SET_PROPERTY(GLOBAL PROPERTY _CMAKE_${_name}_DESCRIPTION "${_desc}" )
|
||||
ENDFUNCTION(ADD_FEATURE_INFO)
|
||||
|
||||
|
||||
|
||||
FUNCTION(SET_PACKAGE_PROPERTIES _name _props)
|
||||
IF(NOT "${_props}" STREQUAL "PROPERTIES")
|
||||
MESSAGE(FATAL_ERROR "PROPERTIES keyword is missing in SET_PACKAGE_PROPERTIES() call.")
|
||||
ENDIF()
|
||||
|
||||
SET(options ) # none
|
||||
SET(oneValueArgs DESCRIPTION URL TYPE PURPOSE )
|
||||
SET(multiValueArgs ) # none
|
||||
|
||||
CMAKE_PARSE_ARGUMENTS(_SPP "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
|
||||
|
||||
IF(_SPP_UNPARSED_ARGUMENTS)
|
||||
MESSAGE(FATAL_ERROR "Unknown keywords given to SET_PACKAGE_PROPERTIES(): \"${_SPP_UNPARSED_ARGUMENTS}\"")
|
||||
ENDIF()
|
||||
|
||||
IF(_SPP_DESCRIPTION)
|
||||
GET_PROPERTY(_info GLOBAL PROPERTY _CMAKE_${_name}_DESCRIPTION)
|
||||
IF(_info AND NOT "${_info}" STREQUAL "${_SPP_DESCRIPTION}")
|
||||
MESSAGE(STATUS "Warning: Property DESCRIPTION for package ${_name} already set to \"${_info}\", overriding it with \"${_SPP_DESCRIPTION}\"")
|
||||
ENDIF()
|
||||
|
||||
SET_PROPERTY(GLOBAL PROPERTY _CMAKE_${_name}_DESCRIPTION "${_SPP_DESCRIPTION}" )
|
||||
ENDIF()
|
||||
|
||||
|
||||
IF(_SPP_URL)
|
||||
GET_PROPERTY(_info GLOBAL PROPERTY _CMAKE_${_name}_URL)
|
||||
IF(_info AND NOT "${_info}" STREQUAL "${_SPP_URL}")
|
||||
MESSAGE(STATUS "Warning: Property URL already set to \"${_info}\", overriding it with \"${_SPP_URL}\"")
|
||||
ENDIF()
|
||||
|
||||
SET_PROPERTY(GLOBAL PROPERTY _CMAKE_${_name}_URL "${_SPP_URL}" )
|
||||
ENDIF()
|
||||
|
||||
|
||||
# handle the PURPOSE: use APPEND, since there can be multiple purposes for one package inside a project
|
||||
IF(_SPP_PURPOSE)
|
||||
SET_PROPERTY(GLOBAL APPEND PROPERTY _CMAKE_${_name}_PURPOSE "${_SPP_PURPOSE}" )
|
||||
ENDIF()
|
||||
|
||||
# handle the TYPE
|
||||
IF(NOT _SPP_TYPE)
|
||||
SET(_SPP_TYPE OPTIONAL)
|
||||
ENDIF()
|
||||
|
||||
# List the supported types, according to their priority
|
||||
SET(validTypes "RUNTIME" "OPTIONAL" "RECOMMENDED" "REQUIRED" )
|
||||
LIST(FIND validTypes ${_SPP_TYPE} _typeIndexInList)
|
||||
IF("${_typeIndexInList}" STREQUAL "-1" )
|
||||
MESSAGE(FATAL_ERROR "Bad package property type ${_SPP_TYPE} used in SET_PACKAGE_PROPERTIES(). "
|
||||
"Valid types are OPTIONAL, RECOMMENDED, REQUIRED and RUNTIME." )
|
||||
ENDIF()
|
||||
|
||||
GET_PROPERTY(_previousType GLOBAL PROPERTY _CMAKE_${_name}_TYPE)
|
||||
LIST(FIND validTypes "${_previousType}" _prevTypeIndexInList)
|
||||
|
||||
# make sure a previously set TYPE is not overridden with a lower new TYPE:
|
||||
IF("${_typeIndexInList}" GREATER "${_prevTypeIndexInList}")
|
||||
SET_PROPERTY(GLOBAL PROPERTY _CMAKE_${_name}_TYPE "${_SPP_TYPE}" )
|
||||
ENDIF()
|
||||
|
||||
ENDFUNCTION(SET_PACKAGE_PROPERTIES)
|
||||
|
||||
|
||||
|
||||
FUNCTION(_FS_GET_FEATURE_SUMMARY _property _var _includeQuiet)
|
||||
|
||||
SET(_type "ANY")
|
||||
IF("${_property}" MATCHES "REQUIRED_")
|
||||
SET(_type "REQUIRED")
|
||||
ELSEIF("${_property}" MATCHES "RECOMMENDED_")
|
||||
SET(_type "RECOMMENDED")
|
||||
ELSEIF("${_property}" MATCHES "RUNTIME_")
|
||||
SET(_type "RUNTIME")
|
||||
ELSEIF("${_property}" MATCHES "OPTIONAL_")
|
||||
SET(_type "OPTIONAL")
|
||||
ENDIF()
|
||||
|
||||
IF("${_property}" MATCHES "PACKAGES_FOUND")
|
||||
SET(_property "PACKAGES_FOUND")
|
||||
ELSEIF("${_property}" MATCHES "PACKAGES_NOT_FOUND")
|
||||
SET(_property "PACKAGES_NOT_FOUND")
|
||||
ENDIF()
|
||||
|
||||
|
||||
SET(_currentFeatureText "")
|
||||
GET_PROPERTY(_EnabledFeatures GLOBAL PROPERTY ${_property})
|
||||
|
||||
FOREACH(_currentFeature ${_EnabledFeatures})
|
||||
|
||||
# does this package belong to the type we currently want to list ?
|
||||
GET_PROPERTY(_currentType GLOBAL PROPERTY _CMAKE_${_currentFeature}_TYPE)
|
||||
IF(NOT _currentType)
|
||||
SET(_currentType OPTIONAL)
|
||||
ENDIF()
|
||||
|
||||
IF("${_type}" STREQUAL ANY OR "${_type}" STREQUAL "${_currentType}")
|
||||
|
||||
# check whether the current feature/package should be in the output depending on whether it was QUIET or not
|
||||
SET(includeThisOne TRUE)
|
||||
# skip QUIET packages, except if they are REQUIRED or INCLUDE_QUIET_PACKAGES has been set
|
||||
IF((NOT "${_currentType}" STREQUAL "REQUIRED") AND NOT _includeQuiet)
|
||||
GET_PROPERTY(_isQuiet GLOBAL PROPERTY _CMAKE_${_currentFeature}_QUIET)
|
||||
IF(_isQuiet)
|
||||
SET(includeThisOne FALSE)
|
||||
ENDIF()
|
||||
ENDIF()
|
||||
|
||||
IF(includeThisOne)
|
||||
|
||||
SET(_currentFeatureText "${_currentFeatureText}\n * ${_currentFeature}")
|
||||
GET_PROPERTY(_info GLOBAL PROPERTY _CMAKE_${_currentFeature}_REQUIRED_VERSION)
|
||||
IF(_info)
|
||||
SET(_currentFeatureText "${_currentFeatureText} (required version ${_info})")
|
||||
ENDIF(_info)
|
||||
GET_PROPERTY(_info GLOBAL PROPERTY _CMAKE_${_currentFeature}_DESCRIPTION)
|
||||
IF(_info)
|
||||
SET(_currentFeatureText "${_currentFeatureText} , ${_info}")
|
||||
ENDIF(_info)
|
||||
GET_PROPERTY(_info GLOBAL PROPERTY _CMAKE_${_currentFeature}_URL)
|
||||
IF(_info)
|
||||
SET(_currentFeatureText "${_currentFeatureText} , <${_info}>")
|
||||
ENDIF(_info)
|
||||
|
||||
GET_PROPERTY(_info GLOBAL PROPERTY _CMAKE_${_currentFeature}_PURPOSE)
|
||||
FOREACH(_purpose ${_info})
|
||||
SET(_currentFeatureText "${_currentFeatureText}\n ${_purpose}")
|
||||
ENDFOREACH()
|
||||
|
||||
ENDIF(includeThisOne)
|
||||
|
||||
ENDIF("${_type}" STREQUAL ANY OR "${_type}" STREQUAL "${_currentType}")
|
||||
|
||||
ENDFOREACH(_currentFeature)
|
||||
SET(${_var} "${_currentFeatureText}" PARENT_SCOPE)
|
||||
ENDFUNCTION(_FS_GET_FEATURE_SUMMARY)
|
||||
|
||||
|
||||
|
||||
FUNCTION(FEATURE_SUMMARY)
|
||||
# CMAKE_PARSE_ARGUMENTS(<prefix> <options> <one_value_keywords> <multi_value_keywords> args...)
|
||||
SET(options APPEND INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
|
||||
SET(oneValueArgs FILENAME VAR DESCRIPTION WHAT)
|
||||
SET(multiValueArgs ) # none
|
||||
|
||||
CMAKE_PARSE_ARGUMENTS(_FS "${options}" "${oneValueArgs}" "${multiValueArgs}" ${_FIRST_ARG} ${ARGN})
|
||||
|
||||
IF(_FS_UNPARSED_ARGUMENTS)
|
||||
MESSAGE(FATAL_ERROR "Unknown keywords given to FEATURE_SUMMARY(): \"${_FS_UNPARSED_ARGUMENTS}\"")
|
||||
ENDIF()
|
||||
|
||||
IF(NOT _FS_WHAT)
|
||||
MESSAGE(FATAL_ERROR "The call to FEATURE_SUMMARY() doesn't set the required WHAT argument.")
|
||||
ENDIF()
|
||||
|
||||
SET(validWhatParts "ENABLED_FEATURES"
|
||||
"DISABLED_FEATURES"
|
||||
"PACKAGES_FOUND"
|
||||
"PACKAGES_NOT_FOUND"
|
||||
"OPTIONAL_PACKAGES_FOUND"
|
||||
"OPTIONAL_PACKAGES_NOT_FOUND"
|
||||
"RECOMMENDED_PACKAGES_FOUND"
|
||||
"RECOMMENDED_PACKAGES_NOT_FOUND"
|
||||
"REQUIRED_PACKAGES_FOUND"
|
||||
"REQUIRED_PACKAGES_NOT_FOUND"
|
||||
"RUNTIME_PACKAGES_FOUND"
|
||||
"RUNTIME_PACKAGES_NOT_FOUND")
|
||||
|
||||
LIST(FIND validWhatParts "${_FS_WHAT}" indexInList)
|
||||
IF(NOT "${indexInList}" STREQUAL "-1")
|
||||
_FS_GET_FEATURE_SUMMARY( ${_FS_WHAT} _featureSummary ${_FS_INCLUDE_QUIET_PACKAGES} )
|
||||
SET(_fullText "${_FS_DESCRIPTION}${_featureSummary}\n")
|
||||
IF (("${_FS_WHAT}" STREQUAL "REQUIRED_PACKAGES_NOT_FOUND") AND _featureSummary)
|
||||
SET(requiredPackagesNotFound TRUE)
|
||||
ENDIF()
|
||||
|
||||
ELSEIF("${_FS_WHAT}" STREQUAL "ALL")
|
||||
|
||||
SET(allWhatParts "ENABLED_FEATURES"
|
||||
"RUNTIME_PACKAGES_FOUND"
|
||||
"OPTIONAL_PACKAGES_FOUND"
|
||||
"RECOMMENDED_PACKAGES_FOUND"
|
||||
"REQUIRED_PACKAGES_FOUND"
|
||||
|
||||
"DISABLED_FEATURES"
|
||||
"RUNTIME_PACKAGES_NOT_FOUND"
|
||||
"OPTIONAL_PACKAGES_NOT_FOUND"
|
||||
"RECOMMENDED_PACKAGES_NOT_FOUND"
|
||||
"REQUIRED_PACKAGES_NOT_FOUND"
|
||||
)
|
||||
|
||||
SET(title_ENABLED_FEATURES "The following features have been enabled:")
|
||||
SET(title_DISABLED_FEATURES "The following features have been disabled:")
|
||||
SET(title_OPTIONAL_PACKAGES_FOUND "The following OPTIONAL packages have been found:")
|
||||
SET(title_OPTIONAL_PACKAGES_NOT_FOUND "The following OPTIONAL packages have not been found:")
|
||||
SET(title_RECOMMENDED_PACKAGES_FOUND "The following RECOMMENDED packages have been found:")
|
||||
SET(title_RECOMMENDED_PACKAGES_NOT_FOUND "The following RECOMMENDED packages have not been found:")
|
||||
SET(title_REQUIRED_PACKAGES_FOUND "The following REQUIRED packages have been found:")
|
||||
SET(title_REQUIRED_PACKAGES_NOT_FOUND "The following REQUIRED packages have not been found:")
|
||||
SET(title_RUNTIME_PACKAGES_FOUND "The following RUNTIME packages have been found:")
|
||||
SET(title_RUNTIME_PACKAGES_NOT_FOUND "The following RUNTIME packages have not been found:")
|
||||
|
||||
SET(_fullText "${_FS_DESCRIPTION}")
|
||||
FOREACH(part ${allWhatParts})
|
||||
SET(_tmp)
|
||||
_FS_GET_FEATURE_SUMMARY( ${part} _tmp ${_FS_INCLUDE_QUIET_PACKAGES})
|
||||
IF(_tmp)
|
||||
SET(_fullText "${_fullText}\n-- ${title_${part}}\n${_tmp}\n")
|
||||
IF("${part}" STREQUAL "REQUIRED_PACKAGES_NOT_FOUND")
|
||||
SET(requiredPackagesNotFound TRUE)
|
||||
ENDIF()
|
||||
ENDIF()
|
||||
ENDFOREACH()
|
||||
ELSE()
|
||||
MESSAGE(FATAL_ERROR "The WHAT argument of FEATURE_SUMMARY() is set to ${_FS_WHAT}, which is not a valid value.")
|
||||
ENDIF()
|
||||
|
||||
IF(_FS_FILENAME)
|
||||
IF(_FS_APPEND)
|
||||
FILE(APPEND "${_FS_FILENAME}" "${_fullText}")
|
||||
ELSE(_FS_APPEND)
|
||||
FILE(WRITE "${_FS_FILENAME}" "${_fullText}")
|
||||
ENDIF()
|
||||
|
||||
ELSE(_FS_FILENAME)
|
||||
IF(NOT _FS_VAR)
|
||||
MESSAGE(STATUS "${_fullText}")
|
||||
ENDIF()
|
||||
ENDIF()
|
||||
|
||||
IF(_FS_VAR)
|
||||
SET(${_FS_VAR} "${_fullText}" PARENT_SCOPE)
|
||||
ENDIF()
|
||||
|
||||
IF(requiredPackagesNotFound AND _FS_FATAL_ON_MISSING_REQUIRED_PACKAGES)
|
||||
MESSAGE(FATAL_ERROR "feature_summary() Error: REQUIRED package(s) are missing, aborting CMake run.")
|
||||
ENDIF()
|
||||
|
||||
ENDFUNCTION(FEATURE_SUMMARY)
|
||||
|
||||
|
||||
# The stuff below is only kept for compatibility
|
||||
|
||||
FUNCTION(SET_PACKAGE_INFO _name _desc)
|
||||
SET(_url "${ARGV2}")
|
||||
SET(_purpose "${ARGV3}")
|
||||
SET_PROPERTY(GLOBAL PROPERTY _CMAKE_${_name}_DESCRIPTION "${_desc}" )
|
||||
IF(_url MATCHES ".+")
|
||||
SET_PROPERTY(GLOBAL PROPERTY _CMAKE_${_name}_URL "${_url}" )
|
||||
ENDIF()
|
||||
IF(_purpose MATCHES ".+")
|
||||
SET_PROPERTY(GLOBAL APPEND PROPERTY _CMAKE_${_name}_PURPOSE "${_purpose}" )
|
||||
ENDIF()
|
||||
ENDFUNCTION(SET_PACKAGE_INFO)
|
||||
|
||||
|
||||
|
||||
FUNCTION(SET_FEATURE_INFO)
|
||||
SET_PACKAGE_INFO(${ARGN})
|
||||
ENDFUNCTION(SET_FEATURE_INFO)
|
||||
|
||||
|
||||
|
||||
FUNCTION(PRINT_ENABLED_FEATURES)
|
||||
FEATURE_SUMMARY(WHAT ENABLED_FEATURES DESCRIPTION "Enabled features:")
|
||||
ENDFUNCTION(PRINT_ENABLED_FEATURES)
|
||||
|
||||
|
||||
|
||||
FUNCTION(PRINT_DISABLED_FEATURES)
|
||||
FEATURE_SUMMARY(WHAT DISABLED_FEATURES DESCRIPTION "Disabled features:")
|
||||
ENDFUNCTION(PRINT_DISABLED_FEATURES)
|
||||
Loading…
Reference in New Issue
Block a user