mirror of
https://mirrors.bfsu.edu.cn/git/linux.git
synced 2024-12-04 01:24:12 +08:00
0f61f6be1f
Now that we have SYM_FUNC_ALIAS() and SYM_FUNC_ALIAS_WEAK(), use those
to simplify and more consistently define function aliases across
arch/arm64.
Aliases are now defined in terms of a canonical function name. For
position-independent functions I've made the __pi_<func> name the
canonical name, and defined other alises in terms of this.
The SYM_FUNC_{START,END}_PI(func) macros obscure the __pi_<func> name,
and make this hard to seatch for. The SYM_FUNC_START_WEAK_PI() macro
also obscures the fact that the __pi_<func> fymbol is global and the
<func> symbol is weak. For clarity, I have removed these macros and used
SYM_FUNC_{START,END}() directly with the __pi_<func> name.
For example:
SYM_FUNC_START_WEAK_PI(func)
... asm insns ...
SYM_FUNC_END_PI(func)
EXPORT_SYMBOL(func)
... becomes:
SYM_FUNC_START(__pi_func)
... asm insns ...
SYM_FUNC_END(__pi_func)
SYM_FUNC_ALIAS_WEAK(func, __pi_func)
EXPORT_SYMBOL(func)
For clarity, where there are multiple annotations such as
EXPORT_SYMBOL(), I've tried to keep annotations grouped by symbol. For
example, where a function has a name and an alias which are both
exported, this is organised as:
SYM_FUNC_START(func)
... asm insns ...
SYM_FUNC_END(func)
EXPORT_SYMBOL(func)
SYM_FUNC_ALIAS(alias, func)
EXPORT_SYMBOL(alias)
For consistency with the other string functions, I've defined strrchr as
a position-independent function, as it can safely be used as such even
though we have no users today.
As we no longer use SYM_FUNC_{START,END}_ALIAS(), our local copies are
removed. The common versions will be removed by a subsequent patch.
There should be no functional change as a result of this patch.
Signed-off-by: Mark Rutland <mark.rutland@arm.com>
Acked-by: Ard Biesheuvel <ardb@kernel.org>
Acked-by: Catalin Marinas <catalin.marinas@arm.com>
Acked-by: Josh Poimboeuf <jpoimboe@redhat.com>
Acked-by: Mark Brown <broonie@kernel.org>
Cc: Joey Gouly <joey.gouly@arm.com>
Cc: Will Deacon <will@kernel.org>
Acked-by: Peter Zijlstra (Intel) <peterz@infradead.org>
Link: https://lore.kernel.org/r/20220216162229.1076788-3-mark.rutland@arm.com
Signed-off-by: Will Deacon <will@kernel.org>
81 lines
1.7 KiB
ArmAsm
81 lines
1.7 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0-only */
|
|
/*
|
|
* Copyright (C) 2012 ARM Ltd.
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <linux/const.h>
|
|
#include <asm/assembler.h>
|
|
#include <asm/page.h>
|
|
#include <asm/cpufeature.h>
|
|
#include <asm/alternative.h>
|
|
|
|
/*
|
|
* Copy a page from src to dest (both are page aligned)
|
|
*
|
|
* Parameters:
|
|
* x0 - dest
|
|
* x1 - src
|
|
*/
|
|
SYM_FUNC_START(__pi_copy_page)
|
|
alternative_if ARM64_HAS_NO_HW_PREFETCH
|
|
// Prefetch three cache lines ahead.
|
|
prfm pldl1strm, [x1, #128]
|
|
prfm pldl1strm, [x1, #256]
|
|
prfm pldl1strm, [x1, #384]
|
|
alternative_else_nop_endif
|
|
|
|
ldp x2, x3, [x1]
|
|
ldp x4, x5, [x1, #16]
|
|
ldp x6, x7, [x1, #32]
|
|
ldp x8, x9, [x1, #48]
|
|
ldp x10, x11, [x1, #64]
|
|
ldp x12, x13, [x1, #80]
|
|
ldp x14, x15, [x1, #96]
|
|
ldp x16, x17, [x1, #112]
|
|
|
|
add x0, x0, #256
|
|
add x1, x1, #128
|
|
1:
|
|
tst x0, #(PAGE_SIZE - 1)
|
|
|
|
alternative_if ARM64_HAS_NO_HW_PREFETCH
|
|
prfm pldl1strm, [x1, #384]
|
|
alternative_else_nop_endif
|
|
|
|
stnp x2, x3, [x0, #-256]
|
|
ldp x2, x3, [x1]
|
|
stnp x4, x5, [x0, #16 - 256]
|
|
ldp x4, x5, [x1, #16]
|
|
stnp x6, x7, [x0, #32 - 256]
|
|
ldp x6, x7, [x1, #32]
|
|
stnp x8, x9, [x0, #48 - 256]
|
|
ldp x8, x9, [x1, #48]
|
|
stnp x10, x11, [x0, #64 - 256]
|
|
ldp x10, x11, [x1, #64]
|
|
stnp x12, x13, [x0, #80 - 256]
|
|
ldp x12, x13, [x1, #80]
|
|
stnp x14, x15, [x0, #96 - 256]
|
|
ldp x14, x15, [x1, #96]
|
|
stnp x16, x17, [x0, #112 - 256]
|
|
ldp x16, x17, [x1, #112]
|
|
|
|
add x0, x0, #128
|
|
add x1, x1, #128
|
|
|
|
b.ne 1b
|
|
|
|
stnp x2, x3, [x0, #-256]
|
|
stnp x4, x5, [x0, #16 - 256]
|
|
stnp x6, x7, [x0, #32 - 256]
|
|
stnp x8, x9, [x0, #48 - 256]
|
|
stnp x10, x11, [x0, #64 - 256]
|
|
stnp x12, x13, [x0, #80 - 256]
|
|
stnp x14, x15, [x0, #96 - 256]
|
|
stnp x16, x17, [x0, #112 - 256]
|
|
|
|
ret
|
|
SYM_FUNC_END(__pi_copy_page)
|
|
SYM_FUNC_ALIAS(copy_page, __pi_copy_page)
|
|
EXPORT_SYMBOL(copy_page)
|