mirror of
https://mirrors.bfsu.edu.cn/git/linux.git
synced 2024-12-29 14:05:19 +08:00
338c297e08
[ Upstream commitf0616abd4e] Currently, clear_page() uses DC ZVA instruction unconditionally. But it should make sure that DCZID_EL0.DZP, which indicates whether or not use of DC ZVA instruction is prohibited, is zero when using the instruction. Use STNP instead when DCZID_EL0.DZP == 1. Fixes:f27bb139c3("arm64: Miscellaneous library functions") Signed-off-by: Reiji Watanabe <reijiw@google.com> Reviewed-by: Robin Murphy <robin.murphy@arm.com> Link: https://lore.kernel.org/r/20211206004736.1520989-2-reijiw@google.com Signed-off-by: Catalin Marinas <catalin.marinas@arm.com> Signed-off-by: Sasha Levin <sashal@kernel.org>
40 lines
676 B
ArmAsm
40 lines
676 B
ArmAsm
/* SPDX-License-Identifier: GPL-2.0-only */
|
|
/*
|
|
* Copyright (C) 2012 ARM Ltd.
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <linux/const.h>
|
|
#include <asm/assembler.h>
|
|
#include <asm/page.h>
|
|
|
|
/*
|
|
* Clear page @dest
|
|
*
|
|
* Parameters:
|
|
* x0 - dest
|
|
*/
|
|
SYM_FUNC_START_PI(clear_page)
|
|
mrs x1, dczid_el0
|
|
tbnz x1, #4, 2f /* Branch if DC ZVA is prohibited */
|
|
and w1, w1, #0xf
|
|
mov x2, #4
|
|
lsl x1, x2, x1
|
|
|
|
1: dc zva, x0
|
|
add x0, x0, x1
|
|
tst x0, #(PAGE_SIZE - 1)
|
|
b.ne 1b
|
|
ret
|
|
|
|
2: stnp xzr, xzr, [x0]
|
|
stnp xzr, xzr, [x0, #16]
|
|
stnp xzr, xzr, [x0, #32]
|
|
stnp xzr, xzr, [x0, #48]
|
|
add x0, x0, #64
|
|
tst x0, #(PAGE_SIZE - 1)
|
|
b.ne 2b
|
|
ret
|
|
SYM_FUNC_END_PI(clear_page)
|
|
EXPORT_SYMBOL(clear_page)
|