mirror of
https://mirrors.bfsu.edu.cn/git/linux.git
synced 2024-11-19 10:14:23 +08:00
e38361d032
Recent contributions, including to DRM and binder, introduce 64-bit
values in their interfaces. A common motivation for this is to allow
the same ABI for 32- and 64-bit userspaces (and therefore also a shared
ABI for 32/64 hybrid userspaces). Anyhow, the developers would like to
avoid gotchas like having to use copy_from_user().
This feature is already implemented on x86-32 and the majority of other
32-bit architectures. The current list of get_user_8 hold out
architectures are: arm, avr32, blackfin, m32r, metag, microblaze,
mn10300, sh.
Credit:
My name sits rather uneasily at the top of this patch. The v1 and
v2 versions of the patch were written by Rob Clark and to produce v4
I mostly copied code from Russell King and H. Peter Anvin. However I
have mangled the patch sufficiently that *blame* is rightfully mine
even if credit should more widely shared.
Changelog:
v5: updated to use the ret macro (requested by Russell King)
v4: remove an inlined add on big endian systems (spotted by Russell King),
used __ARMEB__ rather than BIG_ENDIAN (to match rest of file),
cleared r3 on EFAULT during __get_user_8.
v3: fix a couple of checkpatch issues
v2: pass correct size to check_uaccess, and better handling of narrowing
double word read with __get_user_xb() (Russell King's suggestion)
v1: original
Signed-off-by: Rob Clark <robdclark@gmail.com>
Signed-off-by: Daniel Thompson <daniel.thompson@linaro.org>
Signed-off-by: Russell King <rmk+kernel@arm.linux.org.uk>
116 lines
2.4 KiB
ArmAsm
116 lines
2.4 KiB
ArmAsm
/*
|
|
* linux/arch/arm/lib/getuser.S
|
|
*
|
|
* Copyright (C) 2001 Russell King
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License version 2 as
|
|
* published by the Free Software Foundation.
|
|
*
|
|
* Idea from x86 version, (C) Copyright 1998 Linus Torvalds
|
|
*
|
|
* These functions have a non-standard call interface to make them more
|
|
* efficient, especially as they return an error value in addition to
|
|
* the "real" return value.
|
|
*
|
|
* __get_user_X
|
|
*
|
|
* Inputs: r0 contains the address
|
|
* r1 contains the address limit, which must be preserved
|
|
* Outputs: r0 is the error code
|
|
* r2, r3 contains the zero-extended value
|
|
* lr corrupted
|
|
*
|
|
* No other registers must be altered. (see <asm/uaccess.h>
|
|
* for specific ASM register usage).
|
|
*
|
|
* Note that ADDR_LIMIT is either 0 or 0xc0000000.
|
|
* Note also that it is intended that __get_user_bad is not global.
|
|
*/
|
|
#include <linux/linkage.h>
|
|
#include <asm/assembler.h>
|
|
#include <asm/errno.h>
|
|
#include <asm/domain.h>
|
|
|
|
ENTRY(__get_user_1)
|
|
check_uaccess r0, 1, r1, r2, __get_user_bad
|
|
1: TUSER(ldrb) r2, [r0]
|
|
mov r0, #0
|
|
ret lr
|
|
ENDPROC(__get_user_1)
|
|
|
|
ENTRY(__get_user_2)
|
|
check_uaccess r0, 2, r1, r2, __get_user_bad
|
|
#ifdef CONFIG_CPU_USE_DOMAINS
|
|
rb .req ip
|
|
2: ldrbt r2, [r0], #1
|
|
3: ldrbt rb, [r0], #0
|
|
#else
|
|
rb .req r0
|
|
2: ldrb r2, [r0]
|
|
3: ldrb rb, [r0, #1]
|
|
#endif
|
|
#ifndef __ARMEB__
|
|
orr r2, r2, rb, lsl #8
|
|
#else
|
|
orr r2, rb, r2, lsl #8
|
|
#endif
|
|
mov r0, #0
|
|
ret lr
|
|
ENDPROC(__get_user_2)
|
|
|
|
ENTRY(__get_user_4)
|
|
check_uaccess r0, 4, r1, r2, __get_user_bad
|
|
4: TUSER(ldr) r2, [r0]
|
|
mov r0, #0
|
|
ret lr
|
|
ENDPROC(__get_user_4)
|
|
|
|
ENTRY(__get_user_8)
|
|
check_uaccess r0, 8, r1, r2, __get_user_bad
|
|
#ifdef CONFIG_THUMB2_KERNEL
|
|
5: TUSER(ldr) r2, [r0]
|
|
6: TUSER(ldr) r3, [r0, #4]
|
|
#else
|
|
5: TUSER(ldr) r2, [r0], #4
|
|
6: TUSER(ldr) r3, [r0]
|
|
#endif
|
|
mov r0, #0
|
|
ret lr
|
|
ENDPROC(__get_user_8)
|
|
|
|
#ifdef __ARMEB__
|
|
ENTRY(__get_user_lo8)
|
|
check_uaccess r0, 8, r1, r2, __get_user_bad
|
|
#ifdef CONFIG_CPU_USE_DOMAINS
|
|
add r0, r0, #4
|
|
7: ldrt r2, [r0]
|
|
#else
|
|
7: ldr r2, [r0, #4]
|
|
#endif
|
|
mov r0, #0
|
|
ret lr
|
|
ENDPROC(__get_user_lo8)
|
|
#endif
|
|
|
|
__get_user_bad8:
|
|
mov r3, #0
|
|
__get_user_bad:
|
|
mov r2, #0
|
|
mov r0, #-EFAULT
|
|
ret lr
|
|
ENDPROC(__get_user_bad)
|
|
ENDPROC(__get_user_bad8)
|
|
|
|
.pushsection __ex_table, "a"
|
|
.long 1b, __get_user_bad
|
|
.long 2b, __get_user_bad
|
|
.long 3b, __get_user_bad
|
|
.long 4b, __get_user_bad
|
|
.long 5b, __get_user_bad8
|
|
.long 6b, __get_user_bad8
|
|
#ifdef __ARMEB__
|
|
.long 7b, __get_user_bad
|
|
#endif
|
|
.popsection
|