initial commit

.SRCINFO

@@ -0,0 +1,23 @@
+pkgbase = sunxi-tools-git
+	pkgdesc = Tools to help hacking Allwinner based devices. (A10, A20, sun4i, sun7i)
+	pkgver = 1.4.2.r178.gdf60a46
+	pkgrel = 1
+	url = https://github.com/linux-sunxi/sunxi-tools
+	arch = i686
+	arch = x86_64
+	arch = arm
+	arch = armv6h
+	arch = armv7h
+	arch = aarch64
+	license = GPL-2.0-or-later
+	makedepends = git
+	depends = libusb
+	depends = dtc
+	depends = glibc
+	depends = zlib
+	provides = sunxi-tools
+	conflicts = sunxi-tools
+	source = git+https://gitea.classfun.cn:4443/mirrors/sunxi-tools.git
+	md5sums = SKIP
+
+pkgname = sunxi-tools-git

.gitignore

@@ -0,0 +1,13 @@
+src
+pkg
+sunxi-tools
+*.deb
+*.rpm
+*.bz2
+*.gz
+*.zip
+*.tgz
+*.pkg.tar.xz
+*.pkg.tar.zst
+*.log
+*.png

PKGBUILD

@@ -0,0 +1,35 @@
+# Maintainer: BigfootACA <bigfoot@classfun.cn>
+# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
+# Contributor: choopm <choopm at 0pointer.org>
+# Contributor: BOYPT <pentie at gmail.com>
+
+pkgname=sunxi-tools-git
+pkgver=1.4.2.r178.gdf60a46
+pkgrel=1
+pkgdesc="Tools to help hacking Allwinner based devices. (A10, A20, sun4i, sun7i)"
+arch=(i686 x86_64 arm armv6h armv7h aarch64)
+url="https://github.com/linux-sunxi/sunxi-tools"
+license=(GPL-2.0-or-later)
+depends=(libusb dtc glibc zlib)
+makedepends=(git)
+conflicts=(sunxi-tools)
+provides=(sunxi-tools)
+source=("git+https://gitea.classfun.cn:4443/mirrors/sunxi-tools.git")
+md5sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "${pkgname%-git}"
+  make
+  make misc
+}
+
+package() {
+  cd "${pkgname%-git}"
+  PREFIX="$pkgdir/usr" make install
+  PREFIX="$pkgdir/usr" make install-misc
+}