pkg-genimage/PKGBUILD

# Maintainer: Filipe Bertelli <filipebertelli@tutanota.com>
# Maintainer: BigfootACA <bigfoot@classfun.cn>

pkgname=genimage
pkgver=17.r6.gd97c672
pkgrel=1
pkgdesc="Tool to generate multiple filesystem and flash images from a tree"
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url=https://github.com/pengutronix/genimage
license=(GPL-2.0-only)
depends=(confuse)
optdepends=(
	'cramfs-tools: mkcramfs'
	'genext2fs'
	'qemu-tools: qemu-img'
	'uboot-tools: mkimage'
	'rauc'
	'android-simg2img: simg2img'
	'simg-tools: simg2img'
)
makedepends=(git)
source=(git+https://gitea.classfun.cn:4443/mirrors/genimage.git)
sha256sums=(SKIP)

pkgver(){
	cd "${srcdir}/${pkgname%-git}"
	git describe --long --tags | sed 's/^v//g' | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	cd "$pkgname"
	./autogen.sh
	./configure \
		--prefix=/usr \
		--enable-silent-rules \
		--disable-dependency-tracking
	make
}

check() {
	cd "$pkgname"
	make -k check
}

package() {
	cd "$pkgname"
	make DESTDIR="$pkgdir" install
}